236 messages | OK, so,
- I have extracted the 6 Basic files from the tap file
- From 2 of them I have separated the the binary data corresponding to the labyrinth levels.
- Maxi, do you want to make any translations in order to get TYRANN in english ? here are the BASIC parts :
(In red, some corrections I made)
Side A, program 1 : TYRANN.A
0 GOSUB10000:L=DEEK(#BFFA):IFPEEK(#9FFF)<85THENCALLL
1 FORI=36809TO36834:POKEI,0:NEXT:FORI=38876TO#97FF:POKEI,0:NEXT
8 IFPEEK(#A000)=100THEN100
10 IFPEEK(#A000)=85THEN5900
20 IFPEEK(#A000)>10ANDPEEK(#A000)<50THENCLS:GOTO100
30 PAPER0:INK3:CLS:PRINT:PRINT:PRINT:GOTO8095
100 CLS:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT"VOUS ETES DES A PRESENT DIGNES DE
110 PRINT:PRINT"DECOUVRIR LE DIXIEME ET DERNIER NIVEAU"
120 PRINT"POUR CELA, RECHARGEZ VOTRE SCENARIO
125 PRINT:PRINT"PUIS LA FACE 'B' DE TYRANN...
130 PRINT:PRINT:PRINT:PRINT:PRINT"BON COURAGE ET QUI SAIT...A BIENTOT!"
140 WAIT600:CALLL
5900 CLS:PRINT:PRINT:PRINT:PRINT:PRINT"SI VOTRE ENREGISTREUR NE POSSEDE PAS"
5910 PRINT:PRINT"DE TELECOMMANDE...STOPPEZ LE VITE !!!"
5915 PING
5920 PRINT:PRINT:PRINT:PRINT:PRINT:WAIT200:PRINT" [espace]"
5930 GETA$:IFA$<>" "THEN5930
5940 PAPER0:GOTO20000
6000 POKE#A000,0
6010 O1=#A000
6020 FORL=1TO6
6030 O1=O1+1:POKEO1,LEN(N$(L))
6035 FORJ=1TOLEN(N$(L))
6036 O1=O1+1:POKEO1,ASC(MID$(N$(L),J,1))
6037 NEXTJ
6040 O1=O1+1:DOKEO1,INT(RI(L)/10):O1=O1+2
6045 DOKEO1,1:O1=O1+2
6050 IFC$(L)=GU$THENPOKEO1,1:GOTO6055
6051 IFC$(L)=MA$THENPOKEO1,2:GOTO6055
6052 IFC$(L)=VO$THENPOKEO1,3:GOTO6055
6053 IFC$(L)=DR$THENPOKEO1,4
6055 O1=O1+1:POKEO1,PV(L)
6057 O1=O1+1:POKEO1,ET(L)
6059 O1=O1+1:POKEO1,OK(L)
6061 O1=O1+1:POKEO1,NI(L)
6063 O1=O1+1:POKEO1,FO(L)
6065 O1=O1+1:POKEO1,QI(L)
6067 O1=O1+1:POKEO1,VI(L)
6069 O1=O1+1:POKEO1,AG(L)
6071 O1=O1+1:POKEO1,AR(L)
6073 O1=O1+1:POKEO1,CA(L)+10:O1=O1+24
6116 NEXTL
7000 CLS:PRINT:PRINT:PRINT:PRINT"VOS PERSONNAGES SONT EN PLACE!"
7010 PRINT:PRINT"ILS ATTENDENT VOS ORDRES AU VILLAGE"
7020 PRINT:PRINT"DE 'GOLANUR'..."
7030 WAIT300
8000 CLS:PRINT:INK3:PAPER0
8010 PRINTSPC(8);CHR$(4);CHR$(27);"JNORSOFT ";CHR$(27)"BPRESENTE..."
8015 PRINT
8020 PRINT:PRINT:PRINTSPC(12);CHR$(27);"A";CHR$(27)"JTYRANN";CHR$(4)
8025 PRINT:PRINT:PRINT
8030 PRINT:PRINT" ";CHR$(27);"E";CHR$(96)" NORSOFT 1984"
8040 PRINT:PRINT:PRINT" Vos personnages nous ont fait part
8050 PRINT"de leur desir de passer a l'action
8060 PRINT"dans les plus brefs delais...
8070 PRINT"nous ne perdrons donc pas leur temps
8080 PRINT"dans des presentations a n'en plus
8090 PRINT"finir !!! Pour cela, mettez votre
8091 PRINT"magneto sur 'Play'... A TOUT DE SUITE!
8095 N=INT(PEEK(#A000)*4/5)+1:IFN>7THENN=7
8100 PRINT:PRINT" L'ESCALIER DU VILLAGE VOUS MENERA
8110 PRINT:PRINT"DIRECTEMENT A LA PROFONDEUR ";CHR$(27);"L";CHR$(27);"F";N
8120 CLOAD"":REM0
10000 REM **** ATMOS OU ORIC-1 ? ****
10010 IFPEEK(#C001)=#CCTHEN15000
10020 DOKE#B000,#E6CA
10030 DOKE#B002,#E804
10040 DOKE#B004,621
10050 DOKE#B006,623
10055 DOKE#B008,#F42D
10100 RETURN
15000 REM
15005 DOKE#B000,#E76A
15010 DOKE#B002,#E93D
15020 DOKE#B004,634
15030 DOKE#B006,638
15035 DOKE#B008,#F88F
15100 RETURN
20000 DEFFNA(X)=INT(RND(1)*X)+1
20010 READGU$,MA$,VO$,DR$
21100 FORI=1TO6
21110 IFI=4THENPOKE620,7:GOTO21126
21120 POKE620,I
21126 CLS:PRINT:PRINT"******** CREATION PERSONNAGES ********"
21130 PRINT:PRINT:PRINT"NOM DU PERSONNAGE No"I:INPUTN$(I)
21133 DOKE#FB,DEEK(#276):DOKE#FD,DEEK(#277)
21135 IFLEN(N$(I))>10THENN$(I)=LEFT$(N$(I),10)
21140 PRINT:PRINT:PRINT"CHOISISSEZ UNE CASTE POUR "N$(I)
21145 PRINT
21150 PRINT"1) GUERRIER"
21151 PRINT"2) MAGICIEN"
21152 PRINT"3) VOLEUR "
21153 PRINT"4) DRUIDE "
21154 NI(I)=1
21160 GETC$:IFVAL(C$)<1ORVAL(C$)>4THEN21160
21170 ONVAL(C$)GOTO21171,21172,21173,21174
21171 C$(I)=GU$:GOTO21180
21172 C$(I)=MA$:GOTO21180
21173 C$(I)=VO$:GOTO21180
21174 C$(I)=DR$
21175 REM
21180 CLS
21190 PRINT:PRINTN$(I)" "C$(I)" NIVEAU "NI(I)
21200 FO(I)=FNA(6)+6
21210 QI(I)=FNA(6)+6
21220 VI(I)=FNA(6)+6
21230 AG(I)=FNA(6)+6
21231 RI(I)=FNA(200)+200
21240 PO=FNA(2)+3:EX(I)=1
21250 IFC$(I)=GU$THENPV(I)=FNA(10)+15:
21260 IFC$(I)=MA$THENPV(I)=FNA(5)+7
21270 IFC$(I)=DR$THENPV(I)=FNA(6)+10
21280 IFC$(I)=VO$THENPV(I)=FNA(5)+12
21290 ET(I)=PV(I):CA(I)=10:CP$(I)="OK":OK(I)=0
21300 PRINT:PRINT:PRINT"FORCE "FO(I)
21310 PRINT"QI "QI(I)
21320 PRINT"VITALITE "VI(I)
21330 PRINT"AGILITE "AG(I)
21335 IFOO(I)=1THEN21390
21336 WAIT50
21340 PRINT:PRINT"VOUS AVEZ "PO" POINTS DE BONUS!"
21350 PRINT"OU LES AJOUTEZ VOUS ?"
21360 PRINT:PRINT"F)ORCE...Q)I...V)ITALITE...A)GILITE...?"
21370 GETP$:
21371 IFP$="F"THENFO(I)=FO(I)+PO:GOTO21380
21372 IFP$="Q"THENQI(I)=QI(I)+PO:GOTO21380
21373 IFP$="V"THENVI(I)=VI(I)+PO:GOTO21380
21374 IFP$="A"THENAG(I)=AG(I)+PO:GOTO21380
21375 GOTO21370
21380 CLS:PRINT:PRINTN$(I)" "C$(I)" NIVEAU 1":PRINT
21385 OO(I)=1
21388 GOTO21300
21390 PRINT:PRINT:PRINT"CE PERSONNAGE VOUS CONVIENT ?...O/N"
21391 GETOK$
21392 IFOK$="O"THEN21400
21395 IFOK$="N"THENCLS:GOTO21396ELSE21391
21396 OK(I)=0:GOTO21110
21400 NEXT
21405 CLS
21410 GOTO6000
21500 DATAGUERRIER,MAGICIEN,VOLEUR,DRUIDE
Side A, program 2 : TYRANN.A1 (Without the Labyrinth DATA, no translation needed)
10 F=DEEK(#B000):G=DEEK(#B002)
11 IFPEEK(#9FFF)=85THEN30
12 POKE#BFFF,PEEK(40959)
13 ONPEEK(#BFFF)-85GOTO24,23,22,21,20
20 POKE7657,3
21 POKE7607,3
22 POKE6456,3
23 POKE5906,3
24 POKE4614,3
30 A=INT(PEEK(#A000)*3/4)+1
40 IFA>7THENA=7
50 B=1650+(A-1)*680:DOKE6,B:DOKE4,36835:POKEB+2039,30
100 CALLF:A=7770:FORI=#400TO#413:POKEI,PEEK(A):A=A+1:NEXT:CALLG
110 CALL#400
120 CALLF:A=7800:FORI=#400TO#45D:POKEI,PEEK(A):A=A+1:NEXT:CALLG
130 CLOAD"":REM
Side A, program 3: TYRANN.A2
0 HIMEM36808:PRINTCHR$(6):B$="AIE!"
1 W1=1:W2=2:W3=DEEK(#B000):W4=DEEK(#B002):W5=26:W9=52:PRINTCHR$(17):CLS:GOTO15
2 OP=0:FORT6=1TO6:IFET(T6)=<0THENET(T6)=0:OK(T6)=3:CF$(T6)="MORT"
3 IFOK(T6)<2THENOP=1
4 NEXTT6:RETURN
6 IFW<36861ORW>38849THENW=DEEK(6)+60
7 AV=0:DOKE6,W-60:RETURN
8 GETA$:GOSUB13:IFVAL(A$)=<0ORVAL(A$)>Q3THEN8
9 RETURN
10 GOTO54989
13 L=FRE(0):RETURN
15 DI=23:C8=150:W6=DEEK(#B004):W7=DEEK(#B006):W8=DEEK(#BFFA)
16 W=36862:GOSUB21000:HIRES:INK5:PRINTCHR$(17):POKEW,19:DOKE6,W-60
18 GOTO45
20 POKE773,12:GETA$:POKE773,39:CALLW3:GOSUB13:H2=H2+1
21 IFH2=5THEN22ELSE30
22 FORUR=1TO6:IFOK(UR)<>1THEN26
23 ET(UR)=ET(UR)-NI(UR)
24 IFET(UR)=<0THENET(UR)=0:OK(UR)=3:CF$(UR)="MORT":GOSUB2:IFOP=0THENU7=1:A$="C"
25 IFOK(UR)=3THENCLS:PRINT:PRINTN$(UR)" VIENS DE TREPASSER!!!":PING
26 NEXTUR:H2=0
30 IFA$="L"THENDI=DI+8ELSE35
31 IFDI>31THENDI=7:GOTO45ELSE45
35 IFA$="J"THENDI=DI-8ELSE37
36 IFDI<7THENDI=31:GOTO45ELSE45
37 IFA$="C"THENCALLW4:TEXT:D2=0:PRINTCHR$(17):GOSUB40000:GOSUB50360:Q=0:GOTO45
40 IFA$="I"THENAV=1:GOTO45
41 IFA$=" "THENAV=2:GOTO45
42 CALLW4:GOTO20
45 POKE#420,DI:GOSUB5500:CALL#430:IFQ=1THENQ=0:CALLW4:GOTO20
50 CALLW4:A=PEEK(#424):G=PEEK(#421):G1=PEEK(#422):D=PEEK(#426)
60 D1=PEEK(#427):A1=PEEK(#425)
70 HIRES:CALLW3:CURSET70,50,3:PRINTCHR$(17):INK5
100 DRAW100,0,1:DRAW0,100,1:DRAW-100,0,1:DRAW0,-100,1
120 GOTO1000+A
200 GOTO1010+G
300 GOTO1020+G1
400 GOTO1030+D
500 GOTO1040+D1
600 GOTO1050+A
700 GOTO1060+A1
800 GOTO1070+G1
900 GOTO1080+D1
910 REM
920 GOTO1100+PEEK(#423)
930 GOTO1110+PEEK(#428)
990 F=PEEK(W):GOSUB30000:GOSUB13:CALLW4:IFY6=1THENY6=0:GOTO18ELSE20
1000 GOTO200
1001 CURSET80,60,3:DRAW80,0,1:DRAW0,80,1:DRAW-80,0,1:DRAW0,-80,1:GOTO200
1005 CURSET95,140,3:DRAW0,-80,1:CURSET145,60,3:DRAW0,80,1:CURSET100,140,3
1006 DRAW0,-73,1:DRAW40,0,1:DRAW0,73,1:CURSET105,105,3:CIRCLE2,1:GOTO1001
1010 GOTO300
1011 CURSET70,50,3:DRAW10,10,1:DRAW0,80,1:DRAW-10,10,1:GOTO400
1015 CURSET70,53,3:DRAW3,4,1:DRAW0,90,1:GOTO1011
1020 GOTO400
1021 CURSET70,60,3:DRAW10,0,1:DRAW0,80,1:DRAW-10,0,1:GOTO400
1025 CURSET70,65,3:DRAW3,0,1:DRAW0,75,1:GOTO1021
1030 GOTO500
1031 CURSET170,50,3:DRAW-10,10,1:DRAW0,80,1:DRAW10,10,1:GOTO600
1035 CURSET170,53,3:DRAW-3,4,1:DRAW0,90,1:GOTO1031
1040 GOTO600
1041 CURSET170,60,3:DRAW-10,0,1:DRAW0,80,1:DRAW10,0,1:GOTO600
1045 CURSET170,65,3:DRAW-3,0,1:DRAW0,75,1:GOTO1041
1050 GOTO700
1051 IFG=0ANDG1=1THENCURSET80,60,3:DRAW-10,0,1:CURSET80,140,3:DRAW-10,0,1
1052 IFD=0ANDD1=1THENCURSET160,60,3:DRAW10,0,1:CURSET160,140,3:DRAW10,0,1
1053 GOTO990
1055 GOTO990
1060 GOTO800
1061 CURSET100,80,3:DRAW40,0,1:DRAW0,40,1:DRAW-40,0,1:DRAW0,-40,1:GOTO800
1065 CURSET112,120,3:DRAW0,-32,1:DRAW16,0,1:DRAW0,32,1:CURSET110,120,3
1066 DRAW0,-35,1
1067 DRAW20,0,1:DRAW0,35,1:CURSET114,107,3:CIRCLE1,1:CURSET100,120,3
1068 DRAW40,0,1:GOTO1061
1070 GOTO900
1071 CURSET80,60,3:DRAW20,20,1:DRAW0,40,1:DRAW-20,20,1:DRAW0,-80,1:GOTO900
1075 CURSET85,135,3:DRAW0,-65,1:DRAW10,10,1:DRAW0,45,1:CURSET87,100,3
1076 CIRCLE1,1: GOTO1071
1080 GOTO910
1081 CURSET140,80,3:DRAW20,-20,1:DRAW0,80,1:DRAW-20,-20,1:DRAW0,-40,1:GOTO910
1085 CURSET145,125,3:DRAW0,-45,1:DRAW10,-10,1:DRAW0,65,1:CURSET147,100,3
1086 CIRCLE1,1: GOTO1081
1090 GOTO920
1091 GOTO920
1095 GOTO920
1100 GOTO930
1101 IFG1=1ORG1=5THEN930
1102 IFG=0THENCURSET70,80,3:DRAW30,0,1:DRAW0,40,1:DRAW-30,0,1:GOTO930
1103 CURSET80,80,3:DRAW20,0,1:DRAW0,40,1:DRAW-20,0,1:GOTO930
1105 IFG1=1ORG1=5THEN930
1106 IFG=0THENCURSET71,120,3:DRAW0,-32,1:DRAW17,0,1:DRAW0,32,1:GOTO1108
1107 CURSET80,85,3:DRAW10,0,1:DRAW0,35,1:CURSET80,88,3:DRAW7,0,1:GOTO1109
1108 CURSET70,85,3:DRAW20,0,1:DRAW0,35,1:CURSET72,105,3:CIRCLE1,1:GOTO1102
1109 DRAW0,32,1:GOTO1103
1110 GOTO990
1111 IFD1=1ORD1=5THEN990
1112 IFD=0THENCURSET170,80,3:DRAW-30,0,1:DRAW0,40,1:DRAW30,0,1:GOTO990
1113 CURSET160,80,3:DRAW-20,0,1:DRAW0,40,1:DRAW20,0,1:GOTO990
1115 IFD1=1ORD1=5THEN990
1116 IFD=0THENCURSET169,120,3:DRAW0,-32,1:DRAW-17,0,1:DRAW0,32,1:GOTO1118
1117 CURSET160,85,3:DRAW-10,0,1:DRAW0,35,1:CURSET160,88,3:DRAW-7,0,1:GOTO1119
1118 CURSET170,85,3:DRAW-20,0,1:DRAW0,35,1:CURSET155,105,3:CIRCLE1,1:GOTO1112
1119 DRAW0,32,1:GOTO1113
1500 IFI=4THENPOKE620,7ELSEPOKE620,I
1505 RETURN
1510 IFW6=634THENDOKEW6,48040ELSEDOKEW6,48000
1520 POKEW7,18:IFW6=634THENDOKE#27C,720
1530 CLS:RETURN
1600 CLS:PRINT:PRINT"CONFIRMEZ VOUS LA RECUPERATION ? O/N
1610 GETA$:IFA$="O"THENU7=0:GOTO1620
1615 IFA$="N"THENRETURN
1616 GOTO1610
1620 FORL=1TO6:ET(L)=1:OK(L)=0:CF$(L)="OK":CA(L)=10:AR(L)=0:FT(L)=10:F4(L)=10
1630 FORU=1TO6:OB$(L,U)="":UT%(L,U)=0:VV%(L,U)=0:NEXTU:NEXTL:RETURN
1700 FO(PT)=500:PRINT:PRINT"SA FORCE EST COLOSSALE !!!
1720 PRINT:PRINT"SON ARMURE EST IMMENSE !!!":CA(PT)=-10:WAITC8*2:RETURN
2000 CALLW4:TEXT:PRINTCHR$(17):GOSUB40000:POKE620,3:CLS
2010 PRINT:PRINT"NE CRAIGNEZ PAS ! VAILLANTS SUJETS
2030 PRINT:PRINT"JE SUIS...WAKHAN'YORL. DIEU DES VERTUS
2040 C9=FNA(6):WAITC8*2:T6=FNA(4):PRINT:PRINTN$(C9)" !!!":POKE49151,PEEK(49151)+1
2060 GOTO2060+T6
2061 FO(C9)=INT(FO(C9)*1.5):GOTO2070
2062 QI(C9)=INT(QI(C9)*1.5):GOTO2070
2063 VI(C9)=INT(VI(C9)*1.5):GOTO2070
2064 AG(C9)=INT(AG(C9)*1.5)
2070 PRINT:PRINT"TES CARACTERISTIQUES CHANGENT!!!":PRINT:PRINT:PRINT" [espace]
2080 REPEAT:GETA$:UNTILA$=" ":RETURN
3000 CALLW3
3005 FORWQ=1TO6:T6=FO(WQ)+VI(WQ)+QI(WQ)+AG(WQ):C9=FO(WQ)*VI(WQ)*QI(WQ)*AG(WQ)
3006 IFEX(WQ)<INT(190000*TAN((Y2+2)/11)/(14-(T6^2.8-C9)/T6^2.1))-8000THEN3060
3007 IFNI(WQ)=15THEN3060
3010 EX(WQ)=0:NI(WQ)=NI(WQ)+1:PV(WQ)=PV(WQ)+FNA(5)+3
3020 I=WQ:CALLW4:GOSUB41300:IFPV(WQ)>99THENPV(WQ)=99
3040 Y0=1:PRINT:PRINT:PRINT:PRINTN$(WQ)" MONTE D'UN NIVEAU!!!
3050 FORC1=1TO6:PING:WAIT15:NEXTC1:WAITC8:CLS
3060 NEXTWQ:CALLW4:IFY0=0THEND0=0:RETURN
3070 Y0=0:GOSUB50360:RETURN
4000 PRINT:PRINT"ETES VOUS D'ACCORD ?...O/N":RETURN
5110 IFAV=1THENW=W-W5:AV=0
5111 IFA=5ANDAV=2THENW=W-W9:AV=0:PING
5112 GOSUB6
5120 IFPEEK(W-W5)=21THENPU=1
5140 RETURN
5210 IFAV=1THENW=W+W1:AV=0
5211 IFA=5ANDAV=2THENW=W+W2:AV=0:PING
5212 GOSUB6
5220 IFPEEK(W+W1)=21THENPU=1
5240 RETURN
5310 IFAV=1THENW=W+W5:AV=0
5311 IFA=5ANDAV=2THENW=W+W9:AV=0:PING
5312 GOSUB6
5320 IFPEEK(W+W5)=21THENPU=1
5340 RETURN
5410 IFAV=1THENW=W-W1:AV=0
5411 IFA=5ANDAV=2THENW=W-W2:AV=0:PING
5412 GOSUB6
5420 IFPEEK(W-W1)=21THENPU=1
5440 RETURN
5500 IFA=1ANDAV=1THEN5530
5510 IFA=5ANDAV=1THEN5530
5515 IFAV=2ANDA<>5THENAV=0:Q=1:RETURN
5520 GOTO5010+(DI+1)/8*100
5530 SHOOT:AV=0:Q=1: EL=110
5550 FORL=1TOLEN(B$):CURSETEL,90,3: CHARASC(MID$(B$,L,1)),0,1:EL=EL+6:NEXTL
5560 T6=FNA(6):L=FNA(6):FORI=1TO14:IFOB$(T6,L)=XX$(I)THEN5580
5565 NEXTI
5570 IFOB$(T6,L)=""THEN5580
5575 OB$(T6,L)="":VV%(T6,L)=0:UT%(T6,L)=0
5576 CLS:PRINT:PRINTN$(T6)" A PERDU QUELQUE CHOSE !
5580 RETURN
6000 CALLW3:L=0:FORU=1TO6:L=L+NI(U):NEXTU
6002 POKE#A000,INT(L/6):O1=#A000:FORL=1TO6:O1=O1+1:POKEO1,LEN(N$(L))
6035 FORJ=1TOLEN(N$(L)):O1=O1+1:POKEO1,ASC(MID$(N$(L),J,1)):NEXTJ
6040 O1=O1+1:DOKEO1,INT(RI(L)/10):O1=O1+2:DOKEO1,INT(EX(L)/10):O1=O1+2
6050 IFC$(L)=GU$THENPOKEO1,1:GOTO6055
6051 IFC$(L)=MA$THENPOKEO1,2:GOTO6055
6052 IFC$(L)=VO$THENPOKEO1,3:GOTO6055
6053 IFC$(L)=DR$THENPOKEO1,4
6055 O1=O1+1:POKEO1,PV(L):IFET(L)<0THENET(L)=0
6057 O1=O1+1:POKEO1,ET(L):O1=O1+1:POKEO1,OK(L):O1=O1+1:POKEO1,NI(L)
6063 O1=O1+1:POKEO1,FO(L):O1=O1+1:POKEO1,QI(L):O1=O1+1:POKEO1,VI(L)
6069 O1=O1+1:POKEO1,AG(L):O1=O1+1:POKEO1,AR(L):O1=O1+1
6073 POKEO1,CA(L)+10
6080 FORJ=1TO6:FORJJ=1TO30:IFOB$(L,J)=XX$(JJ)THENO1=O1+1:POKEO1,JJ:GOTO6100
6095 NEXTJJ:O1=O1+1:POKEO1,0
6100 NEXTJ:FORJ=1TO6:O1=O1+1:DOKEO1,VV%(L,J)
6115 O1=O1+2:POKEO1,UT%(L,J):NEXTJ:NEXTL:POKE#9FFF,PEEK(49151):CALLW4
6117 CLS:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT"METTEZ VOTRE CASSETTE 'SCENARIO' DANS LE MAGNETO
6118 PRINT:PRINT"ET TAPEZ [espace] POUR ENREGISTRER...
6119 REPEAT:GETA$:UNTILA$=" "
6120 CSAVE"TYRSAV.TAP",A#9FFF,EO1:CLS:PRINT:PRINT:PRINT:PRINT:PRINT:PRINTSPC(11)"C'EST FAIT!":WAIT300 //Saving a .tap works, I think, better with euphoric (straight double-click...), here, the file was saved as" TYRAN.SAV" instead.
6130 RETURN
6200 O1=#A000:CALLW3:FORL=1TO6:O1=O1+1:DD=PEEK(O1):FORJ=1TODD:O1=O1+1
6240 N$(L)=N$(L)+CHR$(PEEK(O1)):NEXTJ:O1=O1+1:RI(L)=DEEK(O1)*10
6265 O1=O1+2:EX(L)=DEEK(O1)*10:O1=O1+2
6270 GOTO6270+PEEK(O1)
6271 C$(L)=GU$:GOTO6275
6272 C$(L)=MA$:GOTO6275
6273 C$(L)=VO$:GOTO6275
6274 C$(L)=DR$
6275 O1=O1+1:PV(L)=PEEK(O1):O1=O1+1:ET(L)=PEEK(O1):O1=O1+1:OK(L)=PEEK(O1)
6281 O1=O1+1:NI(L)=PEEK(O1):O1=O1+1:FO(L)=PEEK(O1):O1=O1+1:QI(L)=PEEK(O1)
6287 O1=O1+1:VI(L)=PEEK(O1):O1=O1+1:AG(L)=PEEK(O1)
6291 O1=O1+1:AR(L)=PEEK(O1):O1=O1+1:CA(L)=PEEK(O1)-10
6294 IFPEEK(#A000)=0THENO1=O1+24:GOTO6310
6295 FORJ=1TO6:O1=O1+1:OB$(L,J)=XX$(PEEK(O1)):NEXTJ
6300 FORJ=1TO6:O1=O1+1:VV%(L,J)=DEEK(O1):O1=O1+2:UT%(L,J)=PEEK(O1):NEXTJ
6310 GOTO6311+OK(L)
6311 CF$(L)="OK":GOTO6315
6312 CF$(L)="EMPOI.":GOTO6315
6313 CF$(L)="PARAL.":GOTO6315
6314 CF$(L)="MORT"
6315 NEXTL:CALLW4:RETURN
7000 FT(PT)=FT(PT)-1:PRINTN$(PT)" decoche une fleche...":WAITC8/2:ZAP
7030 IFE=0THENC9=INT(10*AG(PT)/MV(VP(PT))):MP(VP(PT))=MP(VP(PT))-C9:GOTO7050
7040 PRINT:PRINT"Elle se plante dans le mur!":PING:WAITC8:GOTO7070
7050 PRINT:PRINT"1 "MN$(VP(PT))" PERD "C9"PV!!!":GOSUB50070:WAITC8
7070 IFFT(PT)=<0THENPRINT:PRINTN$(PT)" abandonne son arc..."ELSE7080
7075 WAITC8:FORWQ=1TO6:IFOB$(PT,WQ)=XX$(11)THEN7077
7076 NEXTWQ:GOTO7080
7077 OB$(PT,WQ)="":VV%(PT,WQ)=0:AR(PT)=0
7080 RETURN
21000 DIMXX$(30),OB$(6,6),VA%(30),VV%(6,6),AA%(25),PR(12),GA(12)
21002 DIMSL%(6,20),UU%(30),UT%(6,6),PF(14)
21003 DIMS$(20),D$(20),AR(14):DEFFNA(X)=INT(RND(1)*X)+1:PAPER0:INK3
21007 FORNB=1TO30:READXX$(NB):NEXT:FORNB=1TO25:READVA%(NB):NEXT
21009 FORNB=1TO25:READAA%(NB):NEXT:FORNB=1TO20:READS$(NB):NEXT
21010 GU$="GUERRIER":MA$="MAGICIEN":VO$="VOLEUR":DR$="DRUIDE"
21013 FORNB=1TO20:READD$(NB):NEXT:FORNB=48036TO48039:POKENB,32:NEXT
21015 FORNB=1TO30:READUU%(NB):NEXT:FORNB=7TO14:READPF(NB):NEXT
21017 IZ=DEEK(#B0):P9=FRE(0):DOKE#FB,DEEK(#276):DOKE#FD,DEEK(#277)
21020 GOSUB6200:FORY6=1TO6:FT(Y6)=30:F4(Y6)=10:NEXT:GOSUB40000:GOSUB13
22000 D0=0:CB=0:DN=0:POKE620,3
22100 CLS:PRINT:PRINT"******* VILLAGE DE 'GOLANUR' ********
22110 PRINT:PRINT:PRINTSPC(12)"VOUS POUVEZ...:
22120 PRINT:PRINT:PRINT
22121 IFU7=1THENQ3=7:GOTO22185
22130 PRINT" 1)INSPECTER UN PERSONNAGE
22140 PRINT" 2)ACHETER OU VENDRE
22160 PRINT" 3)VOIR LE GRAND ALCHIMISTE
22170 PRINT" 4)DESCENDRE DANS LE LABYRINTHE
22180 PRINT:PRINT" 5)SAUVEGARDE SCENARIO
22181 IFU7=0THENQ3=5:GOTO22190
22185 PRINT" 6)RECUPERATION PERSONNAGES
22186 PRINT" 7)QUITTER LE JEU
22190 GOSUB8:IFVAL(A$)=7THENCALLW8
22191 IFU7=1ANDVAL(A$)<6THEN22190
22195 IFVAL(A$)=4THENRETURN
22196 IFVAL(A$)=6THENGOSUB1600:GOSUB40000:GOTO22000
22200 GOSUB23000+(VAL(A$)*1000):GOTO22000
24000 POKE620,3:CLS
24020 PRINT:PRINT"QUI VOULEZ VOUS INSPECTER ?
24030 Q3=6:GOSUB8:I=VAL(A$):GOSUB1500
24050 CLS:PRINTN$(I)" "C$(I)" NIVEAU "NI(I)
24060 PRINT:PRINT"FORCE "FO(I)" EXPERIENCE "EX(I)
24070 PRINT"QI "QI(I):PRINT"VITALITE "VI(I):PRINT"AGILITE "AG(I)
24100 PRINT:PRINT"ETAT INITIAL :"PV(I)" PV":PRINT"ETAT ACTUEL :"INT(ET(I))" PV"
24130 PRINT:PRINT"RICHESSE :"RI(I)" ECUS":PRINT:PRINT"CONDITION PHYSIQUE....."CF$(I)
24136 IFEX(I)=0THENEX(I)=10:GOSUB50300:GOTO24050
24140 PRINT:PRINTSPC(10)"[espace]
24150 REPEAT:GETA$:UNTILA$=" "
24160 CLS:PRINTN$(I)" "C$(I)" NIVEAU "NI(I):PRINT
24170 PRINT"OBJETS POSSEDES... "RI(I)"ECUS
24180 FORO=1TO6:PRINTO;OB$(I,O):NEXTO
24190 PRINT:PRINTSPC(13)"VOUS POUVEZ...:
24200 PRINT:PRINT" 1)LAISSER UN OBJET
24210 PRINT" 2)DONNER UN OBJET
24220 PRINT" 3)DONNER DE L'OR
24230 PRINT" 4)CONTINUER
24240 Q3=4:GOSUB8
24260 GOTO24300+(VAL(A$)*100)
24400 PRINT"LEQUEL?...[7]=AUCUN";
24405 Q3=7:GOSUB8:Q6=VAL(A$)
24406 IFVAL(A$)=7THENCLS:GOTO24160
24407 Q4=I:GOSUB41100
24410 OB$(I,VAL(A$))="":VV%(I,VAL(A$))=0:UT%(I,VAL(A$))=0
24415 GOSUB42100
24420 GOSUB1510:CLS
24430 GOTO24160
24500 PRINT"LEQUEL?...[7]=AUCUN";
24505 Q3=7:GOSUB8:Q4=VAL(A$)
24506 IFQ4=7THENCLS:GOTO24160
24510 PRINT" OK";:WAIT50:PRINT" A QUI?";
24515 FORTE=1TO6:IFOB$(I,Q4)=XX$(TE)THEN24517
24516 NEXTTE:DA=0:GOTO24518
24517 DA=1
24518 Q3=6:GOSUB8:Q7=VAL(A$)
24519 FORIO=1TO25:IFOB$(I,Q4)=XX$(IO)THENZ=AA%(IO)ELSENEXTIO
24520 Q8=Q4:Q4=Q7:GOSUB25800:Q4=Q8
24521 IFNA=1THENNA=0:CLS:PRINT:PRINT" IMPOSSIBLE":WAIT200:GOTO24160
24523 FORHH=7TO14:IFOB$(I,Q4)=XX$(HH)THENGOSUB42200ELSENEXTHH
24524 IFNA=1THENNA=0:CLS:PRINT:PRINT" IMPOSSIBLE":WAIT200:GOTO24160
24525 IFCA(Q7)<10ANDDA=1THENDA=0:GOTO24526ELSE24527
24526 GOSUB1510:PRINT:PRINT:PRINT" DEJA PROTEGE!":WAIT200:GOTO24160
24527 Q9=Q4:Q8=Q6
24528 IFTE<7THENQ6=Q4:Q4=I:GOSUB41100:Q6=TE:Q4=Q7:GOSUB41000:Q4=Q9:Q6=Q8
24529 IFTE<7THENGOSUB40000
24535 FORA=1TO6:IFOB$(Q7,A)=""THENOB$(Q7,A)=OB$(I,Q4):GOTO24547
24540 NEXTA:PING:CLS:PRINT:PRINT:PRINT:PRINT:PRINT" PLEIN!":WAIT50:GOTO24160
24547 VV%(VAL(A$),A)=VV%(I,Q4):UT%(VAL(A$),A)=UT%(I,Q4):UT%(I,Q4)=0
24550 OB$(I,Q4)="":CLS
24560 VV%(I,Q4)=0:GOTO24160
24600 PRINT"A QUI? ";:Q3=6:GOSUB8:Q4=VAL(A$):INPUT"COMBIEN";Q5
24607 IFQ5>RI(I)THENCLS:GOTO24160
24610 CLS:RI(I)=RI(I)-Q5:RI(Q4)=RI(Q4)+Q5:GOTO24160
24700 IFOK(I)>1THENRETURN
24710 IFC$(I)=GU$THENGOSUB24740:GOTO24760
24720 IFC$(I)=VO$THENGOSUB24740:GOTO24760
24730 IFC$(I)=MA$THENGOSUB24740:Q7=23:GOTO24770
24735 GOSUB24740:GOTO24760
24740 CLS:PRINT:PRINTN$(I)" "C$(I)" NIVEAU ";NI(I)
24745 PRINT:PRINT:PRINT" VOUS POUVEZ...
24750 RETURN
24760 Q7=24:GOTO24770
24770 PRINT:PRINT:PRINT" 1)LIRE UN GRIMOIRE
24771 PRINT" 2)UTILISER UN OBJET
24772 PRINT" 3)JETER UN SORT
24773 PRINT" 4)DORMIR
24774 PRINT" 5)CONTINUER
24780 Q3=5:GOSUB8:Q4=VAL(A$)
24781 IFQ4=5THENRETURN
24782 PT=I
24790 ONQ4GOSUB41200,50600,50610,50500
24791 D2=0:PRINT:PRINT:PRINT" [espace]
24792 REPEAT:GETA$:UNTILA$=" ":GOTO24700
25000 REM
25005 GOSUB25998
25050 PRINT:PRINT"QUI VEUT ENTRER ?...[7]=personne
25060 Q3=7:GOSUB8:IFVAL(A$)=7THENRETURN
25070 Q4=VAL(A$)
25080 I=Q4:GOSUB1500
25100 GOSUB25998
25105 REM
25110 PRINT:PRINTN$(Q4)SPC(12)RI(Q4)"ECUS
25120 PRINT:PRINT"DESIREZ VOUS...":PRINT:PRINT"1)ACHETER":PRINT"2)VENDRE"
25125 PRINT"3)QUITTER L'ECHOPE
25130 Q3=3:GOSUB8:Q5=VAL(A$)
25140 IFQ5=3THENGOSUB1510:GOSUB40000:RETURN
25150 ONQ5GOTO25160,25700
25160 REM
25170 IFW6=634THENDOKEW6,48240ELSEDOKEW6,48200
25171 POKEW7,13
25175 II=1:IO=1
25180 CLS:PRINT"JE VOUS PROPOSE:...":PRINT
25190 PRINT"C)HOISIR, S)UITE, Q)UITTER":PRINT
25195 IFII=26THENII=1
25200 FORII=IITO25
25210 IO=IO+1
25211 IFII=26THENII=1
25212 Z=AA%(II)
25215 GOSUB25800:IFNA=1THENNA=0:II=II+1:GOTO25211
25216 IFII<10THENPRINT" ";
25220 PRINTII;XX$(II);
25230 FORNN=LEN(XX$(II))TO25:PRINT".";:NEXTNN
25240 PRINTVA%(II)
25250 IFIO=6THENIO=0:GOTO25260ELSENEXTII
25260 GETA$:IFA$="S"THEN25180
25280 IFA$="Q"THENGOSUB1510:GOSUB25998:GOTO25110
25290 IFA$="C"THENPRINT:PRINT"TAPEZ LE No DE L'OBJET CHOISI";:GOTO25300
25295 GOTO25260
25300 INPUT"";Q6:IFQ6>25ORQ6<1THEN25300 //Was a 0 here, try to choose object n°0 when you buy an object in TYRANN ;)
25306 IFQ6>6ANDQ6<15THENGOSUB42000
25307 Z=AA%(Q6):GOSUB25800:IFNA=1THENNA=0:GOSUB25997:GOTO25110
25310 FORYU=1TO6:IFOB$(Q4,YU)<>""THEN25315ELSEQ5=YU:GOTO25320
25315 NEXTYU:GOSUB1510:GOSUB25995:GOTO25110
25320 IFVA%(Q6)>RI(Q4)THENGOSUB1510:PRINT:PRINT:GOTO25330ELSE25335
25330 PRINT" DEHORS ESCROC!":WAIT200:GOSUB25998:GOTO25110
25335 IFQ6>6THEN25342
25340 IFCA(Q4)<10THENGOSUB1510:PRINT:PRINT:GOTO25341ELSE25342
25341 PRINT:PRINT" VOUS AVEZ DEJA UNE PROTECTION!":WAIT200:GOSUB25998:GOTO25110
25342 RI(Q4)=RI(Q4)-VA%(Q6):IFQ6=11THENFT(Q4)=30
25344 IFQ6>6ANDQ6<15THENAR(Q4)=PF(Q6)
25350 VV%(Q4,Q5)=VA%(Q6)/2:OB$(Q4,Q5)=XX$(Q6):UT%(Q4,Q5)=UU%(Q6)
25355 IFQ6<7THENGOSUB41000
25356 GOSUB1510:GOSUB25998
25360 PRINT:PRINTN$(Q4)" "RI(Q4)"ECUS":A$="1":GOTO25160
25700 GOSUB25998:PRINT:PRINTN$(Q4)" "RI(Q4)"ECUS"
25701 PRINT:PRINT"QUE DESIREZ VOUS VENDRE ?...[7]=rien":PRINT:PRINT
25710 FORII=1TO6:PRINT" "RIGHT$(STR$(II),1)") "OB$(Q4,II);
25730 FORI1=LEN(OB$(Q4,II))TO19:PRINT".";:NEXTI1
25740 PRINTVV%(Q4,II)"ECUS"
25750 NEXTII
25760 Q3=7:GOSUB8:Q6=VAL(A$):IFQ6=7THENGOSUB25998:GOTO25110
25775 GOSUB41100:II=Q6:GOSUB42300
25780 RI(Q4)=RI(Q4)+VV%(Q4,Q6):OB$(Q4,Q6)=""
25785 VV%(Q4,Q6)=0:UT%(Q4,Q6)=0
25790 GOSUB25998:GOTO25110
25800 IFC$(Q4)=GU$THEN25890
25801 IFC$(Q4)=MA$THEN25870
25802 IFC$(Q4)=VO$THEN25850
25803 IFC$(Q4)=DR$THEN25810
25810 IFZ>0THEN25820ELSERETURN
25820 IFZ=2ORZ=3THENRETURN
25830 IFZ=5THENRETURN
25840 NA=1:RETURN
25850 IFZ>0THEN25851ELSERETURN
25851 IFZ=3THENRETURN
25852 IFZ=6ORZ=7THENRETURN
25853 NA=1:RETURN
25870 IFZ>0THEN25871ELSERETURN
25871 IFZ=4THENRETURN
25872 NA=1:RETURN
25890 IFZ=7THENRETURN
25891 IFZ>3THENNA=1:RETURN
25892 RETURN
25995 CLS:PRINT:PRINT:PRINT:PRINT:PRINT" VOUS ETES DEJA PLEIN!":WAIT200
25996 GOTO25998
25997 GOSUB1510:PRINT:PRINTSPC(9)"IMPOSSIBLE!":WAIT200
25998 CLS
25999 PRINT:PRINT"************** ECHOPPE ***************":RETURN
26000 CLS:PRINT:PRINT"QUI VEUT ENTRER ?":Q3=6:GOSUB8:Q4=VAL(A$)
26020 CLS:PRINT:PRINT" ****** SOINS ******":PRINT:PRINT"BIENVENUE A VOUS "N$(Q4)" !"
26025 IFOK(Q4)>0THEN26100
26026 IFET(Q4)=>PV(Q4)THEN26090
26030 C9=NI(Q4)*4
26040 PRINT:PRINT"JE VOUS DEMANDE "C9" ECUS
26050 PRINT:PRINT"PAR PV GUERIS...":GOSUB4000
26060 GETA$:IFA$<>"O"THEN26090
26070 IFRI(Q4)<C9THENRETURN
26080 REPEAT:RI(Q4)=RI(Q4)-C9:ET(Q4)=ET(Q4)+1:UNTILRI(Q4)<C9ORET(Q4)=PV(Q4)
26090 PRINT:PRINT" A BIENTOT!":WAITC8:GOSUB40000:RETURN
26100 IFOK(Q4)=3THEN26170
26110 C9=30*NI(Q4)
26120 PRINT:PRINT"VOTRE MAL SERA GUERI POUR "C9" ECUS":GOSUB4000
26130 GETA$:IFA$<>"O"THEN26090
26140 IFRI(Q4)<C9THENRETURN
26150 RI(Q4)=RI(Q4)-C9:OK(Q4)=0:CF$(Q4)="OK"
26160 GOTO26090
26170 C9=NI(Q4)*NI(Q4)*100
26180 PRINT:PRINT"VOTRE AME SERA SAUVEE POUR "C9" ECUS":GOSUB4000
26190 GETA$:IFA$<>"O"THEN26090
26200 IFRI(Q4)<C9THENRETURN
26210 RI(Q4)=RI(Q4)-C9:OK(Q4)=0:CF$(Q4)="OK":ET(Q4)=1
26220 GOTO26090
27000 DOKE#B000,#E6CA:DOKE#B002,#E804:DOKE#B004,621:DOKE#B006,623:END
28000 CLS:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT" PATIENCE! JE FAIS LE MENAGE!!!":GOSUB6000
28005 CALLW3:FORT6=#A000TOO1:POKET6,64:NEXT:CALLW4:RETURN
30000 IFPU=0THEN30012
30005 PU=0:IFSS=1THENZAP:PRINT:PRINT"LA SOURIS DISPARAIT DANS UN TROU !!!":SS=0
30012 IFF=0THENRETURN
30013 IFF>24THENRETURN
30020 Y6=1:IFF<16THENGOSUB53000:Y6=1:GOTO30100
30030 IFF=18THENGOSUB50800:GOTO30100
30031 IFF<>19THEN30050
30040 PRINT:PRINT"UN ESCALIER MONTE...L'EMPRUNTEZ VOUS ?":CALLW4
30041 GETA$:IFA$="N"THENY6=0:CLS:RETURN
30042 IFA$<>"O"THEN30041ELSEDN=DN-1:W=W-680
30043 IFW<36835THENDN=0:W=W+680:GOSUB6ELSE30045
30044 CALLW4:TEXT:PRINTCHR$(17):GOSUB40000:POKE620,3:GOSUB22000:DI=23:RETURN
30045 GOSUB6:Y6=1:RETURN
30050 IFF<>20THEN30060
30051 PRINT:PRINT"UN ESCALIER DESCEND.L'EMPRUNTEZ VOUS ?":CALLW4
30052 GETA$:IFA$="N"THENY6=0:CLS:RETURN
30053 IFA$<>"O"THEN30052ELSEDN=DN+1:W=W+680:GOSUB6:GOTO30045
30060 IFF=21THENZAP:SHOOT:PRINT"UNE TRAPPE!":CALLW4:WAITC8:CALLW3:GOSUB52700
30070 IFF=22THENGOSUB2000:POKEW,0:RETURN
30080 IFF=23THENGOSUB50800
30100 POKEW,0:GOTO30120
30110 RETURN
30120 PC=FNA(2000)+36835:IFPEEK(PC)<>0THENRETURN
30150 POKEPC,F:RETURN
40000 IFW6=634THENDOKEW6,48760ELSEDOKEW6,48720
40005 POKE48036,32:POKE48037,32:POKE48038,32:POKE48039,32
40010 POKEW7,9:POKE619,16:POKE620,0:CLS
40045 PRINT"PERSONNAGES CASTE PV ET CA":PRINT:CALLW3
40046 POKE48760,20:POKE48761,7:FORL=1TO6:PRINTRIGHT$(STR$(L),1);" "N$(L);
40060 FORII=LEN(N$(L))TO10:PRINT" ";:NEXT:IFOK(L)>0ANDOK(L)<3THEN40067
40061 IFOK(L)=3THENPRINT" MORT":ET(L)=0:GOTO40085
40065 PRINTC$(L);
40066 FORII=LEN(C$(L))TO9:PRINT" ";:NEXT:GOTO40070
40067 PRINTCHR$(27)"L"CF$(L);CHR$(27)"H";
40068 FORII=LEN(CF$(L))+2TO9:PRINT" ";:NEXT
40070 IFPV(L)<10ANDW6=621THENPRINT" ";
40075 PRINTRIGHT$(STR$(PV(L)),2);:PRINT" ";
40076 IFET(L)<10ANDW6=621THENPRINT" ";
40077 PRINTRIGHT$(STR$(INT(ET(L))),2);:PRINT" ";
40078 IFCA(L)=<-10THENPRINT"MI":GOTO40085
40079 IFCA(L)>-1ANDCA(L)<10ANDW6=621THENPRINT" ";
40084 PRINTRIGHT$(STR$(CA(L)),2)
40085 NEXTL
40086 H=49040:FORT=6TO1STEP-1:POKEH,27
40088 IFT=4THENPOKEH+1,7:H=H-40:GOTO40090
40089 POKEH+1,T:H=H-40
40090 NEXT:GOSUB1510:CALLW4:RETURN
41000 T6=CA(Q4):GOTO41010+Q6
41011 T6=T6-15:GOTO41020
41012 T6=T6-10:GOTO41020
41013 T6=T6-7 :GOTO41020
41014 T6=T6-6:GOTO41020
41015 T6=T6-4:GOTO41020
41016 T6=T6-2:GOTO41020
41020 CA(Q4)=T6:RETURN
41100 FORYI=1TO6:IFOB$(Q4,Q6)=XX$(YI)THEN41120
41115 NEXTYI:RETURN
41120 T6=CA(Q4):GOTO41120+YI
41121 T6=T6+15:GOTO41130
41122 T6=T6+10:GOTO41130
41123 T6=T6+7:GOTO41130
41124 T6=T6+6:GOTO41130
41125 T6=T6+4:GOTO41130
41126 T6=T6+2:GOTO41130
41130 CA(Q4)=T6:RETURN
41200 FORII=1TO6:IFOB$(I,II)=XX$(Q7)THEN41220
41210 NEXTII:CLS:PRINT:PRINT:PRINT" VOUS N'EN N'AVEZ PAS!":WAIT200:GOTO41270
41220 CLS:PRINT"GRIMOIRE DE "N$(I):PRINT
41230 IFC$(I)<>MA$THEN41232ELSEC4=1:C3=NI(I)
41231 IFC3>10THENC3=10:GOTO41240ELSE41240
41232 C4=11:C3=NI(I)+10:IFC3>20THENC3=20
41240 FORNB=C4TOC3
41250 PRINTSL%(I,NB)"x "S$(NB);
41255 FORC5=LEN(S$(NB))TO10:PRINT".";:NEXT
41256 PRINTD$(NB):NEXTNB
41270 RETURN
41300 RS=INT((QI(I)-6)/14*(5+FNA(3)))
41320 IFC$(I)=MA$THENC4=1:Q7=23:C3=NI(I):IFC3>10THENC3=10
41321 IFC$(I)=MA$THEN41325
41323 C4=11:Q7=24:C3=NI(I)+10
41324 IFC3>20THENC3=20
41325 FORII=1TO6:IFOB$(I,II)=XX$(Q7)THEN41330ELSENEXT:RETURN
41330 FORNB=C4TOC3:SL%(I,NB)=1:NEXTNB
41340 IFRS=0THENRETURN
41345 IFC3>10THENC3=C3-10
41350 FORC5=1TORS:NB=FNA(C3)+C4-1:SL%(I,NB)=SL%(I,NB)+1:NEXTC5
41360 RETURN
41370 IFC$(I)<>MA$THEN41385ELSE41390
41385 IFC$(I)<>DR$THEND2=1:RETURN
41390 CLS:PRINT:INPUT"QUEL SORT ";SO$(I)
41400 FORC5=1TO20:IFSO$(I)=S$(C5)THEN41410
41405 NEXTC5:D2=1:RETURN
41410 IFSL%(I,C5)=0THENCLS:PRINT:PRINT" IMPOSSIBLE!":D2=1:WAITC8:RETURN
41420 GOTO41430+C5
41431 GOSUB41500:RETURN
41432 GOSUB41510:RETURN
41433 GOSUB41500:IFD2=1THENRETURNELSEGOSUB41520:RETURN
41434 GOSUB41500:RETURN
41435 GOSUB41500:RETURN
41436 GOSUB41500:RETURN
41437 GOSUB41500:RETURN
41438 GOSUB41500:IFD2=1THENRETURNELSEGOSUB41520:RETURN
41439 GOSUB41500:RETURN
41440 GOSUB41500:RETURN
41441 GOSUB41530:RETURN
41442 GOSUB41500:RETURN
41443 GOSUB41500:RETURN
41444 GOSUB41530:RETURN
41445 GOSUB41500:RETURN
41446 GOSUB41530:RETURN
41447 GOSUB41500:RETURN
41448 GOSUB41530:RETURN
41449 GOSUB41500:RETURN
41450 GOSUB41510:IFD2=1THENRETURN
41451 GOSUB41530:RETURN
41500 IFCB<>1THEND2=1:RETURN
41505 D2=0:RETURN
41510 IFCB<>0THEND2=1:RETURN
41515 D2=0:RETURN
41520 IFC1=1THENVP(I)=1:RETURN
41521 CLS:PRINT:PRINT"SUR QUEL MONSTRE ?":Q3=C1:GOSUB8:VP(I)=VAL(A$):RETURN
41530 CLS:PRINT:PRINT"SUR QUI ?":Q3=6:GOSUB8:PG(I)=VAL(A$):RETURN
41540 Z0=0:CLS:PRINT:FORII=1TO6:IFUT%(I,II)>0THENPRINTII") "OB$(I,II):Z0=1
41551 NEXTII:IFZ0=0THEND2=1:CLS:RETURN
41555 PRINT:PRINT"LEQUEL ? [7=aucun]":Q3=7:GOSUB8:OU(I)=VAL(A$)
41556 IFOU(I)=7THEND2=1:CLS:RETURN
41560 IFUT%(I,OU(I))=0THEND2=1:CLS:RETURN
41565 V1=41431:V2=41441:V3=41433
41566 F9=UT%(I,OU(I))
41570 GOTO41570+F9
41571 GOTOV2
41572 GOTOV2
41573 GOTOV2
41574 GOTO41585
41575 GOTOV1
41576 GOTO41505
41577 GOTOV3
41578 GOTOV3
41579 GOTOV1
41580 GOTOV1
41585 SS=1:GOTO41505
42000 FORHH=7TO14:FOROP=1TO6:IFOB$(Q4,OP)=XX$(HH)THEN42050
42040 NEXTOP:NEXTHH:RETURN
42050 NA=1:RETURN
42100 FORHH=7TO14:IFOB$(I,VAL(A$))=XX$(HH)THENAR(I)=0:FT(I)=0:RETURN
42120 NEXTHH:RETURN
42200 FORHH=7TO14:FOROP=1TO6:IFOB$(Q7,OP)=XX$(HH)THENNA=1:RETURN
42230 NEXTOP:NEXTHH:AR(Q7)=AR(I):FT(Q7)=FT(I):AR(I)=0:FT(I)=0
42240 RETURN
42300 FORHH=7TO14:IFOB$(Q4,II)=XX$(HH)THENAR(Q4)=0:FT(Q4)=0:RETURN
42320 NEXTHH:RETURN
42500 T1=7-E+(10-E1):T2=FNA(20):IFT1<T2THENE=0:RETURN
42540 E=1:RETURN
42600 IFF1<0THENF1=0
42620 IFF1>0THEN42630ELSEFR=0:C9=0:F1=1:RETURN
42630 FR=FNA(F1/3+1)-1:F1=F1+1:IFFR=<0THENFR=0:C9=0
42640 RETURN
42650 C6=FNA(3)-1:IFC6=0THENRETURN
42680 C7=FNA(3):CLS:PRINT:PRINT"1 "MN$(MT)" JETTE UN SORT...":WAITC8
42690 IFC7=1THEN42740
42691 IFC7=2ANDY2>4THEN42791
42700 FORY=1TO6:IFMI(MT)>QI(Y)THENCA(Y)=CA(Y)+2
42720 IFCA(Y)>10THENCA(Y)=10
42730 NEXTY:RETURN
42740 FORY=1TO6:IFOK(Y)=3THENNEXTY:RETURN
42750 IFMI(MT)<QI(Y)THENNEXTY:RETURN
42755 C9=INT(MI(MT)*D/VI(Y)):ET(Y)=ET(Y)-C9:PRINTN$(Y)" PERD "C9" PV"
42780 IFET(Y)<=0THENOK(Y)=3:CF$(Y)="MORT":PRINTN$(Y)" SUCCOMBE"
42790 WAITC8:NEXTY:C9=0:RETURN
42791 FORY=1TOC1:MF(Y)=MF(Y)*2:NEXT:RETURN
42800 PRINTN$(VM(MT))" SUCCOMBE":OK(VM(MT))=3:CF$(VM(MT))="MORT":WAITC8:RETURN
50030 QQ=FNA(7):GOTO50040+QQ
50041 O$="frappe":RETURN
50042 O$="cogne":RETURN
50043 O$="poignarde":RETURN
50044 O$="tabasse":RETURN
50045 O$="bouscule":RETURN
50046 O$="cingle":RETURN
50047 O$="lacere":RETURN
50050 QQ=FNA(4):GOTO50060+QQ
50061 O1$="et loupe":RETURN
50062 O1$="et echoue":RETURN
50063 O1$="et manque":RETURN
50064 O1$="et rate":RETURN
50065 VP(PT)=JJ:IFKO(JJ)=3THENRETURN
50066 MP(JJ)=MP(JJ)-C9
50067 PRINT"1 "MN$(JJ)" PERD "C9" PV!!!"
50070 IFKO(VP(PT))=3THEN50090
50080 IFMP(VP(PT))>0THEN50090
50085 PRINT"ET MEURT!!!":KO(VP(PT))=3
50090 RETURN
50100 PRINT:O1=FNA(7):IFO1>1THEN50130
50115 IFKO(VP(PT))>0THEN50130
50120 PRINT"1 "MN$(VP(PT))" frappe le chien..":OB$(PT,OU(PT))=""
50121 PRINT:PRINT"Le chien meurt !!!"
50125 VV%(PT,OU(PT))=0:UT%(PT,OU(PT))=0:WAITC8:RETURN
50130 C9=INT(350/MV(VP(PT)))
50135 MP(VP(PT))=MP(VP(PT))-C9
50140 PRINT"1 "MN$(VP(PT))" PERD "C9" PV!!!":GOSUB50070:WAITC8:RETURN
50150 PRINT
50155 IFKO(VP(PT))>0THEN50190
50160 O1=FNA(10):IFO1>1THEN50190
50170 PRINT"1 "MN$(VP(PT))" le frappe...il meurt!":OB$(PT,OU(PT))=""
50175 VV%(PT,OU(PT))=0:UT%(PT,OU(PT))=0:WAITC8:RETURN
50190 C9=INT(850/MV(VP(PT)))
50195 MP(VP(PT))=MP(VP(PT))-C9
50196 PRINT"1 "MN$(VP(PT))" PERD "C9" PV!!!":GOSUB50070:WAITC8:RETURN
50200 F4(PT)=F4(PT)-1:IFF4(PT)>0THEN50230
50220 OB$(PT,OU(PT))="":VV%(PT,OU(PT))=0:UT%(PT,OU(PT))=0
50225 CLS:PRINT:PRINT"L'EPEE MAGIQUE EST CASSEE!!!":PING:WAITC8:RETURN
50230 RETURN
50300 PO=FNA(2)+1:PRINT:PRINT"VOUS AVEZ "PO" POINTS DE BONUS..."
50330 PRINT"OU LES METTEZ VOUS ?..1) FORCE...2) QI3) VITALITE...4) AGILITE";
50340 Q3=4:GOSUB8:GOTO50350+VAL(A$)
50351 FO(I)=FO(I)+PO:RETURN
50352 QI(I)=QI(I)+PO:Z4(I)=QI(I):RETURN
50353 VI(I)=VI(I)+PO:RETURN
50354 AG(I)=AG(I)+PO:RETURN
50360 D0=1
50370 GOSUB1510:POKE620,3:POKE619,16:CLS
50375 GOSUB2:IFOP=0THENU7=1:GOSUB22000:RETURN
50380 PRINTSPC(9)"******* CAMP *******
50390 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT" VOUS POUVEZ...
50400 PRINT:PRINT" 1) INSPECTER UN PERSONNAGE
50410 PRINT" 2) PLIER BAGAGES
50415 PRINT" 3) TEMPORISER LES COMBATS
50420 Q3=3:GOSUB8
50425 IFVAL(A$)=3THENCLS:PRINT:PRINT:PRINT:PRINT" QUEL TEMPS ?...1 a 400"ELSE50430
50426 INPUTC8:IFC8<1ORC8>400THENC8=200
50427 GOTO50370
50430 CB=0:IFVAL(A$)=1THENGOSUB24000:GOTO50370
50440 GOSUB1510:POKEW7,27:POKE620,3:CLS:RETURN
50500 IFD0=1THENCLS:PRINT:PRINT"CONFIRMEZ VOUS ??? O/N"ELSE50520
50505 GETA$:IFA$<>"O"THENRETURN
50510 NI(I)=NI(I)-1:IFNI(I)<1THENNI(I)=1
50520 CLS:PRINT:PRINTN$(I)" SE REPOSE.....
50530 WAITC8/2:GOSUB41300:RETURN
50600 GOSUB41540:IFD2=1THENRETURN
50605 GOSUB55149:GOSUB40000:GOSUB1500:CLS:RETURN
50610 GOSUB41370:IFD2=1THENRETURN
50615 GOSUB55250:GOSUB40000:GOSUB1500:CLS:RETURN
50800 CALLW4:TEXT:PRINTCHR$(17)
50805 GOSUB40000:POKE620,3:CLS
50810 PRINT:PRINT:PRINT" VOUS ETES EN FACE D'UN COFFRE!!!
50830 PRINT:PRINT"L'OUVREZ VOUS ? O/N
50840 GETA$:IFA$="N"THENRETURN
50841 IFA$<>"O"THEN50840
50850 PRINT:PRINT"QUI SE DEVOUE ?
50860 Q3=6:GOSUB8:Q4=VAL(A$)
50865 IFOK(Q4)>1THEN50850
50870 IFC$(Q4)=VO$THENC9=FNA(20)+NI(Q4):GOTO50885
50880 C9=FNA(8)+5+(NI(Q4)*2)
50885 IFC9>AG(Q4)THEN51000
50895 IFF=23THEN50907
50896 C9=FNA(3):IFC9=3THENRI(Q4)=RI(Q4)+(FNA(100)+100)*NI(Q4)ELSE50900
50897 PRINT:PRINT"DE L'OR!!!!!":GOTO50940
50900 C9=FNA(11)+14:IFC9=24ORC9=23ORC9=19THEN50900
50906 GOTO50910
50907 C9=FNA(6)+24:IFC9=25THENC9=19:VA%(C9)=15000:GOTO50910
50908 VA%(C9)=FNA(100)*100+10000
50910 FORT6=1TO6:IFOB$(Q4,T6)=""THENOB$(Q4,T6)=XX$(C9):GOTO50920
50915 NEXT:PRINT:PRINT"QUEL DOMMAGE!!! "N$(Q4)
50916 PRINT:PRINT"VOUS N'AVEZ PAS LA PLACE POUR PRENDRE
50917 PRINT:PRINT"LE TRESOR!!!...:1 "XX$(C9):WAITC8*3:RETURN
50920 PRINT:PRINTN$(Q4)" A TROUVE QUELQUE CHOSE!":PING
50930 VV%(Q4,T6)=VA%(C9)/2:UT%(Q4,T6)=UU%(C9)
50940 WAITC8*2:RETURN
51000 EXPLODE:PRINT:PRINT"LE PIEGE S'EST DECLENCHE!!!":WAITC8*2
51010 C9=FNA(4)*NI(Q4):ET(Q4)=ET(Q4)-C9
51015 IFET(Q4)=<0THENOK(Q4)=3:CF$(Q4)="MORT":ET(Q4)=0:GOTO51025
51020 C9=FNA(3)-1:GOTO51021+C9
51021 GOTO51025
51022 OK(Q4)=1:CF$(Q4)="EMPOI":GOTO51025
51023 OK(Q4)=2:CF$(Q4)="PARAL":GOTO51025
51025 GOSUB2:IFOP=0THENRETURN
51030 IFC$(Q4)=VO$THEN50895ELSE50805
52000 REM
52001 IFD0=0THENCLS:PRINT:PRINT:PRINT" NOUS SOMMES AU VILLAGE!":RETURN
52005 CLS
52010 PRINT"NOUS NOUS DIRIGEONS VERS ";:GOTO52015+(DI+1)/8
52016 PRINT"LE NORD":GOTO52020
52017 PRINT"L'EST":GOTO52020
52018 PRINT"LE SUD":GOTO52020
52019 PRINT"L'OUEST":GOTO52020
52020 T6=W-36835
52021 F8=INT(T6/680)+1:PRINT:T6=T6-(F8-1)*680-27:F6=INT(T6/26)
52022 F7=T6-F6*26
52029 PRINT"NOUS SOMMES A "F6"CASES SUD
52030 PRINT:PRINT"ET A "F7"CASES EST
52040 PRINT:PRINT"DE L'ENTREE DU NIVEAU 1
52060 PRINT:PRINT:PRINT"NOUS NOUS TROUVONS AU NIVEAU "F8
52070 PRINT:PRINTSPC(9)"[espace]
52080 REPEAT:GETA$:UNTILA$=" ":RETURN
52500 POKE620,3:CLS:T6=0:IFY0=C1THENY0=0:RETURN
52505 Y2=0:Y0=0:FORWQ=1TO6:IFOK(WQ)<>3THENY2=Y2+NI(WQ):T6=T6+1
52507 NEXTWQ:Y2=Y2/T6:IFD>15THEND=15
52520 Y3=INT((D-Y2+1)*1000*Y2/(18-D)+FNA(10)*Y2)
52531 Y4=INT(Y3/(FNA(3)+10))*C1+FNA(10)
52540 FORWQ=1TO6:IFOK(WQ)<>3THENEX(WQ)=EX(WQ)+Y3:RI(WQ)=RI(WQ)+Y4
52545 NEXTWQ
52550 CLS:PRINT:PRINT"CETTE VICTOIRE RAPPORTE AUX SURVIVANTS
52560 PRINT:PRINTY3" POINTS D'EXPERIENCE...":PRINT:PRINTY4" ECUS
52570 WAIT600:CLS:GOSUB3000:RETURN
52600 IFMS(MT)=1THENRETURN
52620 Y5=FNA(2)
52630 IFY5=2THENCLS:PRINT:PRINT"1 "MN$(MT)" FUIT!":KO(MT)=3:Y0=Y0+1:RETURN
52640 RETURN
52700 FORT6=1TO6:C9=FNA(5):IFOK(T6)<>3THEN52725ELSE52740
52725 ET(T6)=ET(T6)-C9
52730 IFET(T6)>0THEN52740
52731 OK(T6)=3:CF$(T6)="MORT":PRINTN$(T6)" VIENS DE MOURIR !":CALLW4:WAITC8
52740 CALLW3:CLS:NEXTT6:Y6=0:GOSUB2:IFOP=0THENU7=1
52750 RETURN
53000 Y2=0:FORL=1TO6:Y2=Y2+NI(L):NEXT:Y2=INT(Y2/6)
53005 D=FNA(2)+FNA(3)+Y2-3+DN+F:C9=D:IFC9>15THENC9=15
53010 IX=IZ:GOTO53020+C9
53021 GOTO53080
53022 IX=IX+21:GOTO53080
53023 IX=IX+45:GOTO53080
53024 IX=IX+67:GOTO53080
53025 IX=IX+95:GOTO53080
53026 IX=IX+113:GOTO53080
53027 IX=IX+133:GOTO53080
53028 IX=IX+160:GOTO53080
53029 IX=IX+192:GOTO53080
53030 IX=IX+212:GOTO53080
53031 IX=IX+241:GOTO53080
53032 IX=IX+265:GOTO53080
53033 IX=IX+285:GOTO53080
53034 IX=IX+313:GOTO53080
53035 IX=IX+342
53080 FORI=1TO6:F2(I)=CA(I):F3(I)=FO(I):F0(I)=VI(I):NEXTI
53085 FORI=1TO6:KO(I)=0:NEXT:Y7=1
53100 C1=0:C2=0:SQ=0:PM=(FNA(4)+11)*D*2
53110 REPEAT:C1=C1+1:NB=FNA(10):DOKE#B0,IX:FORZ=1TONB:READJ$(NB),M0(NB),M1(NB)
53140 GOSUB13:NEXTZ
53145 MN$(C1)=J$(NB):MS(C1)=M0(NB):MG(C1)=M1(NB):MF(C1)=(FNA(40)+D)*D
53150 IFNI(1)<4THENMF(C1)=(FNA(25)+D)*D
53160 IFMG(C1)=3THENMI(C1)=FNA(10)+5+D:C2=C2+1:SQ=SQ+MI(C1):GOTO53170
53165 MI(C1)=0
53170 MV(C1)=FNA(13)+5+INT(D/2):MA(C1)=FNA(10)+2+D
53190 MP(C1)=(FNA(11)+4)*D:MC(C1)=(INT(D/2)+FNA(D)-11)*(-1):PM=PM-MP(C1)
53191 IFMC(C1)<-4THENMC(C1)=-4
53215 UNTILPM<0:CALLW4:TEXT:PRINTCHR$(17)
53222 PAPER0:GOSUB40000:GOSUB53230:GOTO53500
53230 PM=0:CLS:GOSUB1510:POKE620,3:CLS:POKE48040,20
53236 PRINT" ********** COMBAT **********":PRINT
53240 FORI=1TOC1:IFKO(I)=3THEN53251
53250 PRINT" No"I"= 1"MN$(I)
53251 NEXT:POKE48360,17
53252 POKE48361,7:PLOT1,8,"++++++++++++++++++++++++++++++++++++"
53260 IFW6=634THENDOKEW6,48400ELSEDOKEW6,48360
53265 POKEW7,9
53270 IFW3=#E76ATHENDOKE#27C,360:DOKE#278,48440
53280 RETURN
53500 CALLW3:NB=6+C1:FORI=1TONB:IFI>6THEN53550
53540 PR(I)=AG(I):GOTO53560
53550 PR(I)=MA(I-6)
53560 NEXTI:E=1:FORX=1TONB
53570 FORI=1TONB
53580 IFPR(I)<=PR(E)THEN53600
53590 E=I
53600 NEXTI
53610 GA(X)=E:PR(E)=0:NEXTX:CALLW4:GOSUB13
53650 GOSUB2
53652 IFOP=0THEN54991
53653 IFY7=1THENY7=0:GOTO53655
53654 GOSUB40000:GOSUB53230
53655 CLS:D2=0:CB=1:FR=0
53660 D1=0:FORI=1TO6
53661 IFOK(I)=1THENET(I)=ET(I)-NI(I)
53662 GOSUB1500
53665 VP(I)=0:PG(I)=0:CLS
53670 IFOK(I)>1THENCG(I)=3:GOTO53750
53675 PRINT:PRINT" CHOIX DE "N$(I)":..."
53680 PRINT:PRINT" P)ARER
53682 PRINT" C)OMBATTRE
53683 PRINT" U)TILISER
53684 PRINT" S)ORTILEGE
53685 IFD1=1THEN53700
53690 PRINT" F)UIR
53700 GETA$:GOSUB13:IFA$="C"THENCG(I)=0:GOSUB41520:GOTO53740
53702 IFA$="U"THENCG(I)=1:GOSUB41540:GOTO53740
53703 IFA$="S"THENCG(I)=2:GOSUB41370:GOTO53740
53704 IFA$="P"THENCG(I)=3:GOTO53740
53705 IFA$="F"THEN53720
53710 GOTO53700
53720 IFD1=1THEN53700ELSECG(I)=4:D1=1:GOSUB42600:IFFR=0THEN53721ELSE53800
53721 PING:W=W-FNA(300):DI=FNA(4)*8-1:IFW<36835THENW=W+300
53722 IFPEEK(W)<>0THEN53721ELSEGOSUB6:GOTO54995
53730 REM
53740 D1=1:IFD2=1THEND2=0:CLS:GOTO53665
53750 CLS:NEXTI:PRINT:PRINT:PRINT
53760 PRINT"DESIREZ VOUS REFAIRE LES CHOIX...? O/N
53770 GETA$:GOSUB13:IFA$="O"THEN53655
53775 IFA$<>"N"THEN53770
53800 D1=0:FORJ=1TONB:GOSUB13:IFCB=0THENRETURN
53812 GOSUB50030:GOSUB50050:IFGA(J)<7THEN55000
53825 MT=GA(J)-6:IFKO(MT)>1THENGOTO10
53835 POKE619,23:POKE620,0:CLS:PRINT:IFMI(MT)<>0THENGOSUB42650
53841 IFC6<>0THENC6=0:GOTO10
53845 IFD1=2THEND1=0:GOTO53852
53850 VM(MT)=FNA(6)
53851 IFVM(MT)>4THEND1=D1+1:GOTO53845
53852 IFNI(VM(MT))>D-2THENGOSUB52600
53853 E=D:IFY5=2THENY5=0:Y6=Y6+1:WAITC8:GOTO10
53854 E1=CA(VM(MT))
53855 GOSUB2:IFOP=0THEN54990
53856 IFOK(VM(MT))=3THEN53850
53860 IFE>10THENE=10:GOSUB42500ELSEGOSUB42500
53870 IFE=0THEN53890
53880 PRINT"1 "MN$(MT)" "O$" "N$(VM(MT)):PRINT
53881 FORY=1TO10:PRINT".";:WAIT5:NEXTY:PRINT" "O1$:WAITC8:GOTO10
53890 PRINT"1 "MN$(MT)" "O$" "N$(VM(MT)):PRINT
53900 C9=INT(MF(MT)/VI(VM(MT)))+1
53905 IFC9<1THENC9=1
53910 FORY=1TO10:PRINT".";:WAIT5:NEXTY:PRINTN$(VM(MT))" PERD "C9" PV":WAITC8
53920 ET(VM(MT))=ET(VM(MT))-C9
53930 IFET(VM(MT))<=0THENGOSUB42800:GOTO10
53935 IFOK(VM(MT))>0THEN10
53940 IFMG(MT)=0ORMG(MT)=3THEN10
53950 D3=FNA(3)-1
53960 IFD3>0THEN10
53970 IFMG(MT)=2THEN54000
53980 OK(VM(MT))=1:CF$(VM(MT))="EMPOI":PRINTN$(VM(MT))" EST EMPOISONNE!!!"
53990 WAITC8:GOTO10
54000 OK(VM(MT))=2:CF$(VM(MT))="PARAL":PRINTN$(VM(MT))" EST PARALYSE!!!":WAITC8
54989 NEXTJ
54990 IFCB=0THENRETURN
54991 POKE619,16:GOSUB2:IFOP=0THENU7=1:TEXT:GOSUB40000:GOSUB22000:RETURN
54993 OP=1:FORPO=1TOC1:IFKO(PO)<>3THENOP=0
54994 NEXTPO:IFOP=0THEN53650
54995 FORI=1TO6:CA(I)=F2(I):FO(I)=F3(I):VI(I)=F0(I):NEXTI:IFC9=0THEN54999
54997 GOSUB52500:IFD0=1THEN54999
54998 F1=F1-1:GOSUB40000:WAIT400
54999 GOSUB1510:POKEW7,27:POKE620,3:CLS:GOSUB13:RETURN
55000 PT=GA(J):IFFR<>0THEN10
55015 IFVP(PT)<>0ANDKO(VP(PT))=3THEN10
55016 IFPG(PT)<>0ANDOK(PG(PT))=3THEN10
55030 IFOK(PT)>1THEN10
55035 POKE619,16:I=PT:GOSUB1500:CLS:PRINT
55037 FORT6=1TOC1:IFMV(T6)<1THENMV(T6)=1
55040 NEXTT6:GOTO55050+(CG(PT)*100)
55050 E=NI(PT):E1=MC(VP(PT))
55060 GOSUB42500
55061 IFAR(PT)=8THENGOSUB7000:GOTO10
55070 IFE=0THEN55090
55080 PRINTN$(PT)" "O$" 1 "MN$(VP(PT)):PRINT:FORLL=1TO10:PRINT".";:WAIT5:NEXTLL
55081 PRINTO1$:WAITC8:GOTO10
55090 PRINTN$(PT)" "O$" 1 "MN$(VP(PT))
55091 PRINT:FORJJ=1TO10:PRINT".";:WAIT5:NEXTJJ
55092 IFAR(PT)=0THENAR(PT)=1
55100 C9=INT(AR(PT)*FO(PT)/MV(VP(PT)))+FNA(3)
55110 PRINT"LE MONSTRE PERD "C9" PV!!!
55115 MP(VP(PT))=MP(VP(PT))-C9
55120 GOSUB50070:WAITC8:GOTO10
55149 IFCB=0THENFORJ=1TO1
55150 PRINTN$(PT)" utilise 1 "OB$(PT,OU(PT))"...":WAITC8
55160 GOTO55160+(UT%(PT,OU(PT))*2)
55162 ET(PG(PT))=ET(PG(PT))+FNA(10)+5
55163 PRINT:PRINTN$(PG(PT))" VA MIEUX!":GOTO55200
55164 IFOK(PG(PT))<>1THEN55210ELSEOK(PG(PT))=0:CF$(PG(PT))="OK":PRINT
55165 PRINT:PRINTN$(PG(PT))" EST GUERI!!!":GOTO55210
55166 IFOK(PG(PT))<>2THEN55210ELSEOK(PG(PT))=0:CF$(PG(PT))="OK":PRINT
55167 GOTO55165
55168 GOTO55210
55170 FORJJ=1TOC1:C9=INT(QI(PT)^2/MV(JJ)):GOSUB50065
55171 GOTO55185
55172 IFCB=0THENPOKEW-26,0:POKEW+26,0:POKEW-1,0:POKEW+1,0:EXPLODE:GOTO55210
55173 EXPLODE:FORJJ=1TOC1:C9=INT(250/MV(JJ)):GOSUB50065:GOTO55185
55174 GOSUB50100:GOTO55220
55176 GOSUB50150:GOTO55220
55178 PRINT:FORJJ=1TOC1:C9=INT(7*(FO(PT)+QI(PT))/MV(JJ)):GOSUB50065
55179 WAITC8:NEXTJJ:GOSUB50200:GOTO10
55180 GOSUB1700
55181 GOTO55210
55182 GOTO55185
55185 WAITC8:NEXTJJ:GOTO55210
55200 IFET(PG(PT))>PV(PG(PT))THENET(PG(PT))=PV(PG(PT))
55210 OB$(PT,OU(PT))="":VV%(PT,OU(PT))=0:UT%(PT,OU(PT))=0
55220 GOTO10
55250 IFCB=0THENFORJ=1TO1
55260 FORC5=1TO20:IFSO$(PT)=S$(C5)THEN55270
55265 NEXTC5:CLS:GOTO10
55270 SL%(PT,C5)=SL%(PT,C5)-1:IFSL%(PT,C5)<0THENSL%(PT,C5)=0
55275 CLS:PRINT:PRINTN$(PT)" JETTE UN SORT...":WAITC8
55280 GOTO55200+(C5*100)
55300 FORT6=1TOC1:E=NI(PT):E1=MC(T6):GOSUB42500
55304 IFKO(T6)=3THENNEXTT6:GOTO10
55305 IFMS(T6)=1THEN55320
55306 IFMI(T6)>QI(PT)THEN55320
55307 IFKO(T6)=2THEN55330
55310 IFE=0THEN55330
55320 PRINT"1 "MN$(T6)" NE DORT PAS":WAITC8:NEXTT6:GOTO10
55330 PRINT"1 "MN$(T6)" ROUPILLE":WAITC8
55340 KO(T6)=2:MC(T6)=10:MV(T6)=MV(T6)-3:NEXTT6:GOTO10
55350 VI(PT)=VI(PT)+3:GOTO10
55400 CLS:GOSUB52000:RETURN
55500 E=NI(PT):E1=MC(PT):GOSUB42500
55510 IFE=0THEN55530
55520 PRINT:PRINT"1 "MN$(VP(PT))" Y EST INSENSIBLE!!!":WAITC8:GOTO10
55530 C9=FNA(10)+20+NI(PT):PRINT:PRINT"1 "MN$(VP(PT))" PERD "C9" PV!!!"
55540 MP(VP(PT))=MP(VP(PT))-C9:GOSUB50070:WAITC8:GOTO10
55600 FORT6=1TOC1
55605 IFQI(PT)>MI(T6)THENMC(T6)=MC(T6)+NI(PT):MV(T6)=MV(T6)-NI(PT)/2
55610 NEXTT6:GOTO10
55700 FORT6=1TOC1:MF(T6)=MF(T6)/2:NEXTT6:GOTO10
55800 FORT6=1TO6:FO(T6)=FO(T6)*2:NEXTT6:GOTO10
55900 FORT6=1TO6:CA(T6)=-10:NEXTT6:GOTO10
56000 E=NI(PT):E1=MC(VP(PT)):GOSUB42500
56010 IFE=1THENPRINT:PRINT"1 "MN$(VP(PT))" Y EST INSENSIBLE":WAITC8:GOTO10
56020 PRINT"1 "MN$(VP(PT))" EST FOUDROYE!!!":WAITC8:KO(VP(PT))=3:GOTO10
56100 PRINT: FORT6=1TOC1
56104 IFKO(T6)=3THEN56220
56105 IFMS(T6)=1THEN56110
56106 E=NI(PT):E1=MC(T6):GOSUB42500:IFE=0THEN56120
56110 PRINT"1 "MN$(T6)" Y EST INSENSIBLE":WAITC8:NEXTT6:GOTO10
56120 PRINT"1 "MN$(T6)" S'EFFONDRE!!!":WAITC8:KO(T6)=3:NEXTT6:GOTO10
56200 FORT6=1TOC1
56205 C9=FNA(10)+5*NI(PT)
56206 IFKO(T6)=3THEN56220
56210 MP(T6)=MP(T6)-C9:PRINT"1 "MN$(T6)" PERD "C9" PV!!!"
56215 VP(PT)=T6:GOSUB50070
56220 WAITC8/2:NEXTT6:GOTO10
56300 C9=FNA(10)+5:ET(PG(PT))=ET(PG(PT))+C9:PRINT:PRINTN$(PG(PT))" VA MIEUX!":WAITC8
56310 IFET(PG(PT))>PV(PG(PT))THENET(PG(PT))=PV(PG(PT))
56320 GOTO10
56400 PRINT: FORT6=1TOC1
56405 IFKO(T6)>0THEN56480
56410 IFMS(T6)=1THEN56445
56440 E=NI(PT):E1=MC(T6)-INT(D/4):GOSUB42500:IFE=0THEN56450
56445 PRINT"1 "MN$(T6)" S'EN MOQUE!!!":WAITC8:GOTO56480
56450 PRINT"1 "MN$(T6)" EST PETRIFIE!!!":WAITC8:KO(T6)=2:MV(T6)=FNA(3)+3
56480 NEXTT6:GOTO10
56500 FORT6=1TOC1
56504 IFKO(T6)=3THEN56530
56506 C9=4+D+FNA(10):IFC9>QI(PT)THEN56530
56507 IFMS(T6)=1THEN56520
56510 GOTO56530
56520 PRINT"1 "MN$(T6)" DISPARAIT!":WAITC8/2:KO(T6)=3:Y0=Y0+1
56530 NEXTT6:GOTO10
56600 IFOK(PG(PT))<>1THEN10
56610 OK(PG(PT))=0:PRINT:PRINTN$(PG(PT))" EST GUERI!!!":CF$(PG(PT))="OK":GOTO10
56700 FORT6=1TO6:CA(T6)=CA(T6)-4:NEXTT6:GOTO10
56800 F5=PG(PT):IFOK(F5)<>2THEN10
56810 OK(F5)=0:CF$(F5)="OK":PRINT:PRINTN$(F5)" EST GUERI!!!":WAITC8:GOTO10
56900 C9=FNA(2):IFC9=2THENPRINT:PRINT"LES MONSTRES NE SONT PAS AMADOUES!"
56901 IFC9=2THENWAITC8:GOTO10
56902 PRINT:PRINT"LES MONSTRES CESSENT LE COMBAT!!!":WAITC8:FORT6=1TOC1:KO(T6)=3:NEXT
56905 Y0=C1
56910 GOTO10
57000 T6=PG(PT):IFOK(T6)=3THEN57050
57020 ET(T6)=PV(T6):OK(T6)=0:CF$(T6)="OK"
57030 PRINT:PRINTN$(T6)" EST RETABLI !!!":WAITC8
57050 GOTO10
57100 PRINT: FORT6=1TOC1
57103 IFKO(T6)=3THEN57120
57104 IFMS(T6)=1THEN57110
57105 IFQI(PT)/2>MI(T6)THENKO(T6)=3:PRINT"1 "MN$(T6)" PERIT":Y0=Y0+1:GOTO57120
57110 PRINT"1 "MN$(T6)" RICANE!!!
57120 WAITC8:NEXTT6:GOTO10
57200 F5=PG(PT):ET(F5)=1:OK(F5)=0:CF$(F5)="OK":PRINTN$(F5)" VA BIEN!!!"
57210 WAITC8:RETURN
60000 DATAArmure integrale,Armure moyenne,Petite armure,Cotte de mailles
60005 DATAArmure de cuir,Robe
60020 DATADouble hache,Epee a deux mains,Fleau d'armes,Sabre,Arc + fleches
60030 DATAMassue,Dague,Baton
60040 DATASouris blanche,Parchemin,Baril de poudre,Chien de combat
60041 DATABebe dragon
60045 DATAAnti-Poison,Anti-Paralysie
60050 DATAFiole de Soins,Livre de magicien,Livre de druide,Fiole ?
60055 DATAEpee magique,Diademe,Collier,Perle noire,Bague
60060 DATA30000,20000,5000,600,100,50,3500,500,300,50,150,20,30,10,20,600,500
60065 DATA5000,25000,500,500,100,80,80,30000
60090 DATA1,1,1,2,3,0,1,1,2,7,0,0,0,0,0,0,0,0,0,0,0,0,4,5,0
60100 DATAYPAFET,KADEO,KEMPY,TASAWAD,ZADEQ,YDAMA,ISHUL,YEEI,YAMAHN
60110 DATAAZAICH,ASEKO,OKOY,ZINAK,INUK,YEGOP,OHW,MOKAR,XOLUK
60120 DATAKERR,YADEH
60130 DATAEndors les monstres,Localisation,Boule de feu,Terreur,Metal mou
60135 DATAGrande force,Ecran,Foudre,Gele le sang,Montagne de feu,Petit soin
60141 DATAPetrification,Dissipe les esprits,Anti-poison,Renforce armure
60145 DATAAnti-paralysie,Amadoue les monstres,Grand soin,Mot de la mort
60149 DATAVie,0,0,0,0,0,0,0,0,0,0,0,0,0,0,4,5,6,7,8,2,3,1,0,0,10,9,0,0,0,0
60160 DATA15,12,9,7,8,5,4,2
63000 DATAFarceur,,,Orc,,,Serpent,,1,Squelette,1,,Gobelin,,,Rat geant,,,Chacal
63010 DATA,,Feu follet,1,,Zombie,1,2,Loup,,,Troll,,,Sorciere,,3,Spectre,1,3
63020 DATAOmbre,1,2,Homme chat,,,Araignee geante,,1,Cerbere,,,Momie,1,2
63030 DATALoup garou,,,Esprit,1,3,Meduse,,1,Homme sable,,,Vampire,1,2,Geant,,
63040 DATAArchimage,,3,Chimere,,,Scorpion geant,,1,Vortex,1,2,Minotaure,,
63045 DATAGolem,,,Dragon noir,,3,Titan,,,Colosse,,,Eminence noire,1,1
63046 DATALuminescence,1,3,Hydre,,1,Chevalier blanc,,3,Cthulhu,1,2
SIde B, program 1 : TYRANN.B
1 L=DEEK(#BFFA)
5 IFPEEK(#9FFF)<85THENCALLL
10 IFPEEK(#A000)<11THEN200
20 IFPEEK(#A000)=85THEN200
30 IFPEEK(#C001)<>#CCTHEN100
40 DOKE#B000,#E76A:DOKE#B002,#E93D:DOKE#B004,634:DOKE#B006,638:DOKE#B008,F88F
50 IFPEEK(#A000)<>100THEN300
60 CLOAD"":REM0
100 DOKE#B000,#E6CA:DOKE#B002,#E804:DOKE#B004,621:DOKE#B006,623:DOKE#B008,F42D
110 GOTO50
200 CLS:PRINT:PRINT"DESOLE MAIS VOUS SERIEZ ANEANTIS
210 PRINT:PRINT"EN MOINS DE TEMPS QU'IL NE FAUT POUR"
220 PRINT:PRINT"LE DIRE...SI NOUS VOUS LAISSIONS"
230 PRINT:PRINT"ABORDER CE NIVEAU SANS PREPARATION !!!"
240 PRINT:PRINT"RECHARGEZ VOTRE SCENARIO PUIS TYRANN A
250 WAIT500:CALLL
300 CLS:PAPER0:INK6
330 PRINT" HOMMES COURAGEUX !":PRINT
340 PRINT"Vous qui venez de franchir une dure
350 PRINT"etape de combats impitoyables ou le
360 PRINT"sang et les blessures etaient le prix
370 PRINT"de chaque pas... Je vous salue!
380 PRINT:PRINT"C'est a cet endroit precis que
390 PRINT"la reine TYRANN fut jadis condamnee.
400 PRINT"Son peche fut de ne pas savoir
410 PRINT"choisir son epoux entre les deux
420 PRINT"princes des vents; tout deux avides
430 PRINT"de richesses et de puissance...
440 PRINT"Ils sont aujourd'hui les gardiens du
450 PRINT"joyau. TYRANN, elle, repose dans un
460 PRINT"sarcophage de cristal,au plus profond
470 PRINT"du labyrinthe,protegee par d'etranges
480 PRINT"sortileges... Malheur a ceux qui
490 PRINT"parviennent en ce temple sans avoir
500 PRINT"ce qu'il faut!... Honneurs et gloire
510 PRINT"a l'elu courageux!!!
520 PRINT"Maintenant ALLEZ! et que la paix soit
530 PRINT"avec vous!
540 PRINTSPC(20)"WAKAHN'YORL"
550 GOTO60
Side B, Program 2 : TYRAN.B1(Without the binary data of the final level, nothing to translatehere)
5 REM?:?:?:?:?:?"
10 F=DEEK(#B000):G=DEEK(#B002)
50 B=1650
70 DOKE6,B
80 DOKE4,38200
90 POKEB+680,30
100 CALLF:A=2331:FORI=#400TO#413:POKEI,PEEK(A):A=A+1:NEXT:CALLG
110 CALL#400
120 CALLF:A=2351:FORI=#400TO#45D:POKEI,PEEK(A):A=A+1:NEXT:CALLG
125 CALLF:FORI=38876TO#97FF:POKEI,29:NEXT
126 FORI=38170TO38199:POKEI,29:NEXT:CALLG
130 CLOAD"":REM0
SIDE B, PROGRAM 3 :TYRANN.B2
0 HIMEM38170:PRINTCHR$(6):B$="AIE!"
1 W1=1:W2=2:W3=DEEK(#B000):W4=DEEK(#B002):W5=26:W9=52:PRINTCHR$(17):CLS:GOTO15
2 OP=0:FORT6=1TO6:IFET(T6)=<0THENET(T6)=0:OK(T6)=3:CF$(T6)="MORT"
3 IFOK(T6)<2THENOP=1
4 NEXTT6:RETURN
6 IFW<38200THENW=W+676ELSEIFW>38876THENW=W-676
7 AV=0:DOKE6,W-60:RETURN
8 GETA$:GOSUB13:IFVAL(A$)=<0ORVAL(A$)>Q3THEN8
9 RETURN
10 GOTO54989
13 L=FRE(0):RETURN
15 DI=23:C8=120:W6=DEEK(#B004):W7=DEEK(#B006):W8=DEEK(#B008)
16 W=38200:PAPER0:GOSUB21000:HIRES:INK5:PRINTCHR$(17):POKEW,19:DOKE6,W-60
18 GOTO45
20 POKE773,20:GETA$:POKE773,39:CALLW3:GOSUB13:H2=H2+1
21 IFH2=5THEN22ELSE30
22 FORUR=1TO6:IFOK(UR)<>1THEN26
23 ET(UR)=ET(UR)-NI(UR)
24 IFET(UR)=<0THENET(UR)=0:OK(UR)=3:CF$(UR)="MORT":GOSUB2:IFOP=0THENU7=1
25 IFOK(UR)=3THENCLS:PRINT:PRINTN$(UR)" VIENS DE TREPASSER!!!":PING
26 NEXTUR:H2=0
30 IFA$="L"THENDI=DI+8ELSE35
31 IFDI>31THENDI=7:GOTO45ELSE45
35 IFA$="J"THENDI=DI-8ELSE37
36 IFDI<7THENDI=31:GOTO45ELSE45
37 IFA$="C"THENCALLW4:TEXT:D2=0:PRINTCHR$(17):GOSUB40000:GOSUB50360:Q=0:GOTO45
38 IFA$="V"THENCALLW4:TEXT:D2=0:PRINTCHR$(17):GOSUB40000:GOSUB22000:Q=0:GOTO45 //"VILLAGE OF GOLANUR that comes with you" (a cheat by soft-bug)
40 IFA$="I"THENAV=1:GOTO45
41 IFA$=" "THENAV=2:GOTO45
42 CALLW4:GOTO20
45 POKE#420,DI:GOSUB5500:CALL#430:IFQ=1THENQ=0:CALLW4:GOTO20
50 CALLW4:A=PEEK(#424):G=PEEK(#421):G1=PEEK(#422):D=PEEK(#426)
60 D1=PEEK(#427):A1=PEEK(#425)
70 HIRES:CALLW3:CURSET70,50,3:PRINTCHR$(17):IFTD<>0THENGOSUB2100:INKTD:GOTO100
71 INK5
100 DRAW100,0,1:DRAW0,100,1:DRAW-100,0,1:DRAW0,-100,1
120 GOTO1000+A
200 GOTO1010+G
300 GOTO1020+G1
400 GOTO1030+D
500 GOTO1040+D1
600 GOTO1050+A
700 GOTO1060+A1
800 GOTO1070+G1
900 GOTO1080+D1
910 REM
920 GOTO1100+PEEK(#423)
930 GOTO1110+PEEK(#428)
990 REM
991 F=PEEK(W):GOSUB30000:CALLW4:IFY6=1THENY6=0:GOTO18ELSE20
1000 GOTO200
1001 CURSET80,60,3:DRAW80,0,1:DRAW0,80,1:DRAW-80,0,1:DRAW0,-80,1:GOTO200
1005 CURSET95,140,3:DRAW0,-80,1:CURSET145,60,3:DRAW0,80,1:CURSET100,140,3
1006 DRAW0,-73,1:DRAW40,0,1:DRAW0,73,1:CURSET105,105,3:CIRCLE2,1:GOTO1001
1010 GOTO300
1011 CURSET70,50,3:DRAW10,10,1:DRAW0,80,1:DRAW-10,10,1:GOTO400
1015 CURSET70,53,3:DRAW3,4,1:DRAW0,90,1:GOTO1011
1020 GOTO400
1021 CURSET70,60,3:DRAW10,0,1:DRAW0,80,1:DRAW-10,0,1:GOTO400
1025 CURSET70,65,3:DRAW3,0,1:DRAW0,75,1:GOTO1021
1030 GOTO500
1031 CURSET170,50,3:DRAW-10,10,1:DRAW0,80,1:DRAW10,10,1:GOTO600
1035 CURSET170,53,3:DRAW-3,4,1:DRAW0,90,1:GOTO1031
1040 GOTO600
1041 CURSET170,60,3:DRAW-10,0,1:DRAW0,80,1:DRAW10,0,1:GOTO600
1045 CURSET170,65,3:DRAW-3,0,1:DRAW0,75,1:GOTO1041
1050 GOTO700
1051 IFG=0ANDG1=1THENCURSET80,60,3:DRAW-10,0,1:CURSET80,140,3:DRAW-10,0,1
1052 IFD=0ANDD1=1THENCURSET160,60,3:DRAW10,0,1:CURSET160,140,3:DRAW10,0,1
1053 GOTO990
1055 GOTO990
1060 GOTO800
1061 CURSET100,80,3:DRAW40,0,1:DRAW0,40,1:DRAW-40,0,1:DRAW0,-40,1:GOTO800
1065 CURSET112,120,3:DRAW0,-32,1:DRAW16,0,1:DRAW0,32,1:CURSET110,120,3
1066 DRAW0,-35,1
1067 DRAW20,0,1:DRAW0,35,1:CURSET114,107,3:CIRCLE1,1:CURSET100,120,3
1068 DRAW40,0,1:GOTO1061
1070 GOTO900
1071 CURSET80,60,3:DRAW20,20,1:DRAW0,40,1:DRAW-20,20,1:DRAW0,-80,1:GOTO900
1075 CURSET85,135,3:DRAW0,-65,1:DRAW10,10,1:DRAW0,45,1:CURSET87,100,3
1076 CIRCLE1,1: GOTO1071
1080 GOTO910
1081 CURSET140,80,3:DRAW20,-20,1:DRAW0,80,1:DRAW-20,-20,1:DRAW0,-40,1:GOTO910
1085 CURSET145,125,3:DRAW0,-45,1:DRAW10,-10,1:DRAW0,65,1:CURSET147,100,3
1086 CIRCLE1,1: GOTO1081
1090 GOTO920
1091 GOTO920
1095 GOTO920
1100 GOTO930
1101 IFG1=1ORG1=5THEN930
1102 IFG=0THENCURSET70,80,3:DRAW30,0,1:DRAW0,40,1:DRAW-30,0,1:GOTO930
1103 CURSET80,80,3:DRAW20,0,1:DRAW0,40,1:DRAW-20,0,1:GOTO930
1105 IFG1=1ORG1=5THEN930
1106 IFG=0THENCURSET71,120,3:DRAW0,-32,1:DRAW17,0,1:DRAW0,32,1:GOTO1108
1107 CURSET80,85,3:DRAW10,0,1:DRAW0,35,1:CURSET80,88,3:DRAW7,0,1:GOTO1109
1108 CURSET70,85,3:DRAW20,0,1:DRAW0,35,1:CURSET72,105,3:CIRCLE1,1:GOTO1102
1109 DRAW0,32,1:GOTO1103
1110 GOTO990
1111 IFD1=1ORD1=5THEN990
1112 IFD=0THENCURSET170,80,3:DRAW-30,0,1:DRAW0,40,1:DRAW30,0,1:GOTO990
1113 CURSET160,80,3:DRAW-20,0,1:DRAW0,40,1:DRAW20,0,1:GOTO990
1115 IFD1=1ORD1=5THEN990
1116 IFD=0THENCURSET169,120,3:DRAW0,-32,1:DRAW-17,0,1:DRAW0,32,1:GOTO1118
1117 CURSET160,85,3:DRAW-10,0,1:DRAW0,35,1:CURSET160,88,3:DRAW-7,0,1:GOTO1119
1118 CURSET170,85,3:DRAW-20,0,1:DRAW0,35,1:CURSET155,105,3:CIRCLE1,1:GOTO1112
1119 DRAW0,32,1:GOTO1113
1500 IFI=4THENPOKE620,7ELSEPOKE620,I
1505 RETURN
1510 IFW6=634THENDOKEW6,48040ELSEDOKEW6,48000
1520 POKEW7,18:IFW6=634THENDOKE#27C,PEEK(W7)*40
1530 CLS:RETURN
1600 CLS:PRINT:PRINT"CONFIRMEZ VOUS LA RECUPERATION ? O/N"
1610 GETA$:IFA$="O"THENU7=0:GOTO1620
1615 IFA$="N"THENRETURN
1616 GOTO1610
1620 FORL=1TO6:ET(L)=1:OK(L)=0:CF$(L)="OK":RI(L)=0
1626 RS=0:I=L:GOSUB41320
1630 FORU=1TO6:OB$(L,U)="":UT%(L,U)=0:VV%(L,U)=0:NEXTU:NEXTL:RETURN
2000 CALLW4:TEXT:PRINTCHR$(17):GOSUB40000:POKE620,3:CLS
2010 PRINT:PRINT"UNE ALCOVE FERMEE!!!"
2020 PRINT:PRINT"L'INSPECTEZ VOUS ? O/N"
2025 GETA$:IFA$<>"O"THEN2080
2030 PRINT:PRINT"QUI VEUT REGARDER ?":Q3=6:GOSUB8
2031 IFOK(VAL(A$))>1THEN2030
2035 FORT6=1TO6:IFOB$(VAL(A$),T6)=XX$(21)THEN2050
2040 NEXTT6:PRINT:PRINT"LA SERRURE SEMBLE TRES SOLIDE!!!":WAITC8*2:CLS:GOTO2020
2050 CLS:PRINT:PRINT"VOTRE ROSSIGNOL A ETE BIEN UTILE ..."
2060 PRINT:PRINT"MAIS IL EST HORS D'USAGE !":WAITC8:C9=VAL(A$):OB$(C9,T6)=""
2061 UT%(C9,T6)=0
2062 WAITC8:CLS:PRINT:PRINT"UN MANUSCRIT ..."
2063 PRINT:PRINT:PRINT"LA MARMITE UTILISEE..."
2064 PRINT:PRINT"DEPOSEZ LES INGREDIENTS...":PRINT:PRINT"LE FEU DU 'LIRAM' FERA LE RESTE !!!"
2065 PRINT:PRINT:PRINT" [espace]"
2066 GETA$:IFA$<>" "THEN2066
2067 CLS:PRINT:PRINT"KALAM SAISIT LES MOTS QUI CHANGENT !!!":PING:WAITC8/2
2070 POKEW,0:RETURN
2080 W=W+26:RETURN
2100 TD=(DI+1)/8:IFTD=4THENTD=6:RETURN
2110 RETURN
5110 IFAV=1THENW=W-W5:AV=0
5111 IFA=5ANDAV=2THENW=W-W9:AV=0:PING
5112 GOSUB6
5120 IFPEEK(W-W5)>0ANDPEEK(W-W5)<16THENPU=1
5140 RETURN
5210 IFAV=1THENW=W+W1:AV=0
5211 IFA=5ANDAV=2THENW=W+W2:AV=0:PING
5212 GOSUB6
5220 IFPEEK(W+W1)>0ANDPEEK(W+W1)<16THENPU=1
5240 RETURN
5310 IFAV=1THENW=W+W5:AV=0
5311 IFA=5ANDAV=2THENW=W+W9:AV=0:PING
5312 GOSUB6
5320 IFPEEK(W+W5)>0ANDPEEK(W+W5)<16THENPU=1
5340 RETURN
5410 IFAV=1THENW=W-W1:AV=0
5411 IFA=5ANDAV=2THENW=W-W2:AV=0:PING
5412 GOSUB6
5420 IFPEEK(W-W1)>0ANDPEEK(W-W1)<16THENPU=1
5440 RETURN
5500 IFA=1ANDAV=1THEN5530
5510 IFA=5ANDAV=1THEN5530
5515 IFAV=2ANDA<>5THENAV=0:Q=1:RETURN
5520 GOTO5010+(DI+1)/8*100
5530 SHOOT:AV=0:Q=1: EL=110
5550 FORL=1TOLEN(B$):CURSETEL,90,3: CHARASC(MID$(B$,L,1)),0,1:EL=EL+6:NEXTL
5560 T6=FNA(6):L=FNA(6)
5570 IFUT%(T6,L)=0THEN5580
5571 IFUT%(T6,L)=34THENTD=0
5575 OB$(T6,L)="":VV%(T6,L)=0:UT%(T6,L)=0
5576 PRINT:PRINTN$(T6)" A PERDU QUELQUE CHOSE !"
5580 RETURN
6000 CALLW3:L=0:FORU=1TO6:L=L+NI(U):NEXTU
6002 POKE#A000,100:O1=#A000:FORL=1TO6:O1=O1+1:POKEO1,LEN(N$(L))
6035 FORJ=1TOLEN(N$(L)):O1=O1+1:POKEO1,ASC(MID$(N$(L),J,1)):NEXTJ
6040 O1=O1+1:DOKEO1,INT(RI(L)/10):O1=O1+2:DOKEO1,EX(L):O1=O1+2
6050 IFC$(L)=GU$THENPOKEO1,1:GOTO6055
6051 IFC$(L)=MA$THENPOKEO1,2:GOTO6055
6052 IFC$(L)=VO$THENPOKEO1,3:GOTO6055
6053 IFC$(L)=DR$THENPOKEO1,4
6055 O1=O1+1:POKEO1,PV(L):IFET(L)<0THENET(L)=0
6057 O1=O1+1:POKEO1,ET(L):O1=O1+1:POKEO1,OK(L):O1=O1+1:POKEO1,NI(L)
6063 O1=O1+1:POKEO1,FO(L):O1=O1+1:POKEO1,QI(L):O1=O1+1:POKEO1,VI(L)
6069 O1=O1+1:POKEO1,AG(L):O1=O1+1:POKEO1,AR(L):O1=O1+1
6073 POKEO1,CA(L)+10
6080 FORJ=1TO6:O1=O1+1:POKEO1,UT%(L,J):NEXTJ:O1=O1+1
6100 FORJ=1TO6:DOKEO1,VV%(L,J):O1=O1+2:NEXTJ:NEXTL:CALLW4
6117 CLS:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT"METTEZ VOTRE CASSETTE 'SCENARIO' DANS LE MAGNETO"
6118 PRINT:PRINT"ET TAPEZ [espace] POUR ENREGISTRER..."
6119 GETA$:IFA$<>" "THEN6119
6120 CSAVE"TYRSAV.TAP",A#9FFF,EO1 //Saving a .tap works, I think, better with euphoric (straight double-click...), here, the file was saved as" TYRAN.SAV" instead.
6130 CLS:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT" C'EST FAIT!":WAIT300:RETURN
6200 O1=#A000:CALLW3
6215 FORL=1TO6:O1=O1+1:DD=PEEK(O1):FORJ=1TODD:O1=O1+1
6240 N$(L)=N$(L)+CHR$(PEEK(O1)):NEXTJ:O1=O1+1:RI(L)=DEEK(O1)*10
6265 O1=O1+2:EX(L)=DEEK(O1):O1=O1+2
6270 GOTO6270+PEEK(O1)
6271 C$(L)=GU$:GOTO6275
6272 C$(L)=MA$:GOTO6275
6273 C$(L)=VO$:GOTO6275
6274 C$(L)=DR$
6275 O1=O1+1:PV(L)=PEEK(O1):O1=O1+1:ET(L)=PEEK(O1):O1=O1+1:OK(L)=PEEK(O1)
6281 O1=O1+1:NI(L)=PEEK(O1):O1=O1+1:FO(L)=PEEK(O1):O1=O1+1:QI(L)=PEEK(O1)
6287 O1=O1+1:VI(L)=PEEK(O1):O1=O1+1:AG(L)=PEEK(O1)
6291 O1=O1+1:AR(L)=PEEK(O1):O1=O1+1:CA(L)=PEEK(O1)-10
6294 IFPEEK(#A000)<>100THENO1=O1+24:GOTO6310
6295 FORJ=1TO6:O1=O1+1:OB$(L,J)=XX$(PEEK(O1)):UT%(L,J)=PEEK(O1):NEXTJ:O1=O1+1
6300 FORJ=1TO6:VV%(L,J)=DEEK(O1):O1=O1+2:NEXTJ
6310 GOTO6311+OK(L)
6311 CF$(L)="OK":GOTO6315
6312 CF$(L)="EMPOI.":GOTO6315
6313 CF$(L)="PARAL.":GOTO6315
6314 CF$(L)="MORT"
6315 NEXTL:CALLW4:RETURN
10000 FORT6=1TO6:IFOB$(T6,6)="SCEPTRE DE PAIX"THEN11000
10010 NEXTT6
10020 CALLW4:EXPLODE:FORT6=1TO6:PAPER3:WAIT4
10030 PAPER1:WAIT4
10050 NEXTT6:PAPER0:W=38200
10060 FORT6=1TO6:ET(T6)=1:PV(T6)=INT(PV(T6)/2)
10070 IFC$(T6)=GU$THENC$(T6)="PLEUTRE":GOTO10090
10071 IFC$(T6)=VO$THENC$(T6)="SIMPLET":GOTO10090
10072 IFC$(T6)=DR$THENC$(T6)="ANE":GOTO10090
10073 IFC$(T6)=MA$THENC$(T6)="STUPIDE"
10090 NEXT:GU$="PLEUTRE":VO$="SIMPLET":DR$="ANE":MA$="STUPIDE":RETURN
11000 CALLW4:TEXT:PRINTCHR$(17):PAPER6:INK4:CLS
11010 PRINT:PRINT" "N$(T6)" S'AVANCE,"
11020 WAIT200:PRINT:PRINT"MAL A L'AISE, VERS LE SARCOPHAGE"
11030 WAIT200:PRINT:PRINT"DE CRISTAL DANS LEQUEL GIT 'TYRANN'
11040 WAIT200:PRINT:PRINT"IL SE REND BIEN COMPTE QUE L'ESPRIT
11050 WAIT200:PRINT:PRINT"TOURMENTE LE GUETTE PAS A PAS...
11060 WAIT200:PRINT:PRINT"IL DEPOSE ENFIN LE SCEPTRE SUR LE
11070 WAIT200:PRINT:PRINT"PIEDESTAL...TOUT LE GROUPE ATTEND...
11080 WAIT400:CLS:INK5:PRINT:PRINT"IL SERAIT TROP LONG DE VOUS CONTER "
11090 WAIT200:PRINT:PRINT"LA FIN DE CETTE HISTOIRE, CAR ELLE "
11100 WAIT200:PRINT:PRINT"DURE TOUJOURS...
11110 WAIT200:PRINT:PRINTN$(T6)" A EPOUSE TYRANN ET REGNE
11120 WAIT200:PRINT:PRINT"A SES COTES DANS LA PAIX...
11125 WAIT200:PRINT:PRINT"SES CINQ COMPAGNON DEVINRENT LES
11140 WAIT200:PRINT:PRINT"MAITRES INCONTESTES DE LEUR CASTE
11150 WAIT200:PRINT:PRINT"ET UNE RUMEUR CIRCULE QU'ILS COMPTENT
11160 WAIT200:PRINT:PRINT"BIEN TOUS REPARTIR A L'AVENTURE !!!
11170 WAIT200:PRINT:PRINT"QUI SAIT ? PEUT-ETRE POUR LA SUITE DE
11180 WAIT200:PRINT:PRINT"CETTE FANTASTIQUE SAGA !!!":WAIT600:CLS:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT
11190 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT" FIN"
11200 WAIT500:POKE#9FFF,T6:GOSUB6000
11300 CLS:PRINT:PRINT" FELICITATIONS A CETTE FAMEUSE
11310 PRINT:PRINT"EQUIPE ! CONSERVEZ VOTRE SCENARIO
11320 PRINT:PRINT"DANS UN ENDROIT SUR ET FAITES NOUS
11330 PRINT:PRINT"PARVENIR VOS CRITIQUES ET SUGGETIONS
11340 PRINT:PRINT"LA SUITE DE TYRRAN, SI ELLE VOIT LE
11350 PRINT:PRINT"JOUR, SERA FAITE EN FONCTION DES
11360 PRINT:PRINT"CRITIQUES EMISES...
11370 PRINT:PRINT:PRINT"A BIENTOT, DONC DANS DE NOUVELLES
11380 PRINT:PRINT"AVENTURES ENCORE PLUS FOLLES!!!
11390 PRINT:PRINT:PRINTSPC(15)"L'equipe de NORSOFT
11400 WAIT2000:END
21000 DIMXX$(45),OB$(6,6),SL%(6,20),UU%(45),UT%(6,6),VV%(6,6),PR(11),GA(11)
21003 DIMS$(20):DEFFNA(X)=INT(RND(1)*X)+1:PAPER0:INK3
21007 FORNB=1TO45:READXX$(NB),UU%(NB):NEXT
21009 FORNB=1TO20:READS$(NB):NEXT
21010 GU$="GUERRIER":MA$="MAGICIEN":VO$="VOLEUR":DR$="DRUIDE"
21013 FORNB=48036TO48039:POKENB,32:NEXT
21017 IZ=DEEK(#B0):P9=FRE(0):DOKE#FB,DEEK(#276):DOKE#FD,DEEK(#277)
21020 GOSUB6200:FORI=1TO6:NI(I)=10:RS=0:GOSUB41320
21021 IFAR(I)=1THENOB$(I,6)="SCEPTRE DE PAIX":UT%(I,6)=0:POKE38546,0
21022 NEXT:IFPEEK(#A000)<>100THENPRINT:PRINT:PRINT:PRINT:PRINT"UN INSTANT SVP !":GOSUB25000
21025 CALLW4:GOSUB40000:POKE620,3:GOTO22109
22000 D0=0:CB=0:POKE620,3:IFMN$(1)="GARDIEN"THENRETURN
22005 IFU7=1THENQ3=5:GOTO22185
22100 CLS: PRINT:PRINT"BONSOIR MESSIRES...JE SUIS LE MAITRE"
22102 PRINT:PRINT"DE LA CHAMBRE...VOUS POUVEZ RECUPERER"
22103 PRINT:PRINT"DES SORTS CONTRE TOUT CE QUE VOUS AVEZ":PRINT:PRINT"OK ?"
22104 GETA$:IFA$="N"THENCLS:GOTO22109ELSEIFA$<>"O"THEN22104
22105 FORI=1TO6:RS=0:GOSUB41320:RI(I)=0:FORT6=1TO6:OB$(I,T6)="":UT%(I,T6)=0
22106 NEXT:NEXT:CLS:PRINT:PRINT" ET VOILA !":WAITC8
22109 CLS:PRINT:PRINT"******* CHAMBRE DES ELUS *******"
22110 PRINT:PRINT:PRINT" VOUS POUVEZ...:"
22120 PRINT:PRINT:PRINT
22130 PRINT" 1)INSPECTER UN PERSONNAGE"
22170 PRINT" 2)LEVER LE CAMP"
22180 PRINT:PRINT" 3)SAUVEGARDE SCENARIO"
22181 IFU7=0THENQ3=3:GOTO22190
22185 CLS:PRINT" 4)RECUPERATION PERSONNAGES"
22186 PRINT" 5)QUITTER LE JEU"
22190 GOSUB8:IFVAL(A$)=5THENCALLW8
22191 IFU7=1ANDVAL(A$)<4THEN22190
22195 IFVAL(A$)=2THENMR=0:Y6=1:RETURN
22196 IFVAL(A$)=4THENGOSUB1600:GOSUB40000:GOTO22000
22200 IFVAL(A$)=3THENGOSUB28000ELSEGOSUB24000
22210 D0=0:CB=0:POKE620,3:GOTO22109
24000 POKE620,3:CLS
24020 PRINT:PRINT"QUI VOULEZ VOUS INSPECTER ?"
24030 Q3=6:GOSUB8:I=VAL(A$):GOSUB1500
24040 IFAR(I)=2THENRETURN
24050 CLS:PRINTN$(I)" "C$(I)
24060 PRINT:PRINT"FORCE "FO(I)
24070 PRINT"QI "QI(I)" MONSTRES TUES:"EX(I)
24080 PRINT"VITALITE "VI(I):PRINT"AGILITE "AG(I)
24100 PRINT:PRINT"ETAT INITIAL :"PV(I)" PV":PRINT"ETAT ACTUEL :"INT(ET(I))" PV"
24130 PRINT:PRINT"RICHESSE :"RI(I)" ECUS":PRINT:PRINT"CONDITION PHYSIQUE....."CF$(I)
24140 PRINT:PRINT" [espace]"
24145 GETA$
24150 IFA$=" "THENCLSELSE24145
24160 CLS:PRINTN$(I)" "C$(I):PRINT
24170 PRINT"OBJETS POSSEDES... "RI(I)"ECUS"
24180 FORO=1TO6:PRINTO;OB$(I,O):NEXTO
24190 PRINT:PRINT" VOUS POUVEZ...:"
24200 PRINT:PRINT" 1)LAISSER UN OBJET
24230 PRINT" 2)CONTINUER
24240 Q3=2:GOSUB8
24260 IFVAL(A$)=2THEN24700
24400 PRINT"LEQUEL?...[7]=AUCUN";
24405 Q3=7:GOSUB8:Q6=VAL(A$)
24406 IFQ6=7THENCLS:GOTO24160
24407 IFUT%(I,Q6)=34THENTD=0
24408 IFOB$(I,Q6)="SCEPTRE DE PAIX"THENAR(I)=0:POKE38546,2
24410 OB$(I,Q6)="":UT%(I,Q6)=0
24420 GOSUB1510:IFTL=1THENRETURN
24430 GOTO24160
24700 IFOK(I)>1THENRETURN
24740 CLS:PRINT:PRINTN$(I)" "C$(I)
24745 PRINT:PRINT:PRINT" VOUS POUVEZ..."
24770 PRINT:PRINT:PRINT" 1)LIRE UN GRIMOIRE"
24771 PRINT" 2)UTILISER UN OBJET"
24772 PRINT" 3)JETER UN SORT
24774 PRINT" 4)CONTINUER
24780 Q3=4:GOSUB8:Q4=VAL(A$)
24781 IFQ4=4THENRETURN
24782 PT=I
24790 ONQ4GOSUB41200,50600,50610:IFTL=1THENRETURN
24791 D2=0:PRINT:PRINT:PRINT" [espace]"
24792 GETA$:IFA$=" "THEN24700ELSE24792
25000 CALLW3:FORI=1TO6:FORL=1TO6:OB$(I,L)="":UT%(I,L)=0:VV%(I,L)=0:NEXT
25002 EX(I)=0:AR(I)=0:NEXT
25005 FORT6=1TO6:IFC$(T6)=GU$THENOB$(T6,1)=XX$(1):UT%(T6,1)=1
25006 IFC$(T6)=VO$THENOB$(T6,1)=XX$(9):UT%(T6,1)=9:VV%(T6,1)=9
25007 IFC$(T6)=MA$THENOB$(T6,1)=XX$(8):UT%(T6,1)=8
25008 IFC$(T6)=DR$THENOB$(T6,1)=XX$(33):UT%(T6,1)=33
25009 NEXT:E=15:GOSUB26500:RETURN
25010 NB=0
25015 VM=FNA(39)
25020 Q3=INT(UU%(VM)/100)
25021 IFNB=1ANDQ3=5THEN25015
25030 GOTO25030+Q3*10
25040 IFC$(L)<>GU$THEN25015
25042 GOTO25080
25050 IFC$(L)<>VO$THEN25015
25052 GOTO25080
25060 IFC$(L)<>DR$THEN25015
25062 GOTO25080
25070 IFC$(L)<>MA$THEN25015
25080 GOSUB26000:IFJJ=7THEN25100
25081 IFD>0THEN25120
25082 IFVM>2ANDVM<6THEN25015
25083 IFVM>14ANDVM<20THEN25015
25090 OB$(L,JJ)=XX$(VM):UT%(L,JJ)=VM:VV%(L,JJ)=VAL(RIGHT$(STR$(UU%(VM)),1))
25100 RETURN
25120 PING:PRINT:PRINTN$(L)" A TROUVE 1 "XX$(VM):WAITC8:D=2:GOTO25090
26000 FORJJ=1TO6:IFUT%(L,JJ)=0THEN26020
26010 NEXTJJ
26020 RETURN
26500 FORC9=1TOE
26510 L=FNA(6):IFOK(L)=3THEN26510
26520 GOSUB25010:NEXTC9:RETURN
28000 CLS:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT" PATIENCE! JE FAIS LE MENAGE!!!":GOSUB6000
28005 CALLW3:FORT6=#A000TOO1:POKET6,64:NEXT:CALLW4:RETURN
30000 IFPU=0THEN30012
30005 PU=0:IFSS=1THENPING:PRINT:PRINT"LE MADEK DETECTE DE LA VIE DEVANT VOUS"
30012 IFF=0THENRETURN
30013 IFF>24THENRETURN
30014 Y6=1:IFF>3THEN30030ELSEGOTO30019+F
30020 Y6=1:GOSUB53000:Y6=1:GOTO30100
30021 GOSUB35990:RETURN
30022 Y6=1:GOSUB10000:RETURN
30030 IFF=18THENGOSUB50800:GOTO30100
30031 IFF<>19THEN30050
30040 PRINT:PRINT"UN ESCALIER MONTE...L'EMPRUNTEZ VOUS ?":CALLW4
30041 GETA$:IFA$="N"THENY6=0:CLS:RETURN
30042 IFA$<>"O"THEN30041
30044 CALLW4:TEXT:SS=0:PRINTCHR$(17):GOSUB40000:POKE620,3:GOSUB22000:DI=23:RETURN
30045 GOSUB6:Y6=1:RETURN
30050 IFF<>20THEN30060
30051 GOSUB35000:RETURN
30060 IFF=21THENCLS:PRINT:PRINT"DES RUNES SONT GRAVEES AU SOL...":Y6=0:RETURN
30070 IFF=22THENGOSUB2000:RETURN
30080 IFF=23THENGOSUB37000:RETURN
30100 POKEW,0:GOTO30120
30110 RETURN
30120 PC=FNA(680)+38200:IFPEEK(PC)<>0THENRETURN
30150 POKEPC,F:RETURN
31000 FORT6=1TO6:IFCG(T6)<>1THENNEXTT6:RETURN
31005 POKE38546,2:POKE619,16:FORT6=1TO5:POKE620,T6:CLS
31006 PRINT:PRINT:PRINT:PRINT:GOTO31006+T6
31007 O$=" LE GLAS":GOTO31020
31008 O$=" SONNE POUR":GOTO31020
31009 O$=" "+N$(PT):GOTO31020
31010 O$="":GOTO31020
31011 O$="LE SCEPTRE EST PERDU !"
31020 C9=1000
31021 SOUND1,C9,0:SOUND2,C9/2,0:SOUND3,C9/3,0
31022 PLAY7,0,1,5000
31050 PRINTO$:WAIT200:NEXTT6:WAITC8*2:Y0=C1
31060 AR(PT)=2:OK(PT)=3:FORT6=1TOC1:KO(T6)=3:NEXTT6:RETURN
35000 FORT6=1TO6:FORC9=1TO6:IFUT%(T6,C9)<21ANDUT%(T6,C9)>0THEN35040
35010 IFUT%(T6,C9)=33ORUT%(T6,C9)=38THEN35040
35020 NEXTC9:NEXTT6:Y6=0:RETURN
35040 C9=0:REPEAT:C9=C9+1
35050 FORT6=50TO150:CURSET10,T6,3:FILL1,1,FNA(7):NEXT:UNTILC9=2:W=W-1:RETURN
35990 CALLW4:TEXT:PRINTCHR$(17) :GOSUB40000:POKE620,3:CLS
36000 C9=1:FORT6=2TO6:IFEX(T6)<EX(T6-1)THENC9=T6
36001 NEXTT6:CLS:PRINT:PRINT"LA PALE LUEUR D'UN OBJET ":PRINT:PRINT"ATTIRE VOTRE REGARD..."
36050 WAITC8*2: PRINT:PRINT"LE PRENEZ VOUS ? O/N"
36060 GETA$:IFA$="N"THEN36100
36065 PRINT:PRINT"QUI LE RAMASSE ?":Q3=6:GOSUB8:Q4=VAL(A$):IFOK(Q4)>1THEN36065
36070 IFQ4=C9THEN36080
36071 CLS:PRINT:PRINT:PRINT"VOUS NE SUPPORTEZ PAS SON ECLAT !!!":GOTO36065
36080 CLS:PRINT:PRINT:PRINT"LOUE SOIT VOTRE COURAGE, "N$(Q4):AR(Q4)=1:POKEW,0
36090 OB$(Q4,6)="SCEPTRE DE PAIX":UT%(Q4,6)=0:WAITC8*2:RETURN
36100 W=W-1:RETURN
37000 CALLW4:TEXT:PRINTCHR$(17):GOSUB40000:POKE620,3:CLS
37010 PRINT:PRINT"JE SUIS LE GARDIEN ";
37020 GOTO37020+(DI+1)/8
37021 PRINT"DU NORD":GOTO37030
37024 PRINT"DE L'OUEST"
37030 PRINT:PRINT"JE VEUX VOTRE OR !...REFUSEZ VOUS ?"
37040 GETA$:IFA$="O"THEN37100
37050 IFA$<>"N"THEN37040
37055 C9=0:FORT6=1TO6:C9=C9+RI(T6):NEXT:IFC9<40000+FNA(30)*100THEN37080
37060 W=W-52:PRINT:PRINT"PASSEZ !":WAITC8*2:FORT6=1TO6:RI(T6)=0:NEXTT6:RETURN //It was written "PASEZ" instead
37080 PRINT:PRINT"VOUS N'AVEZ PAS ASSEZ...RECULEZ VOUS ?":GETA$:IFA$="N"THEN37100
37090 W=38524:RETURN
37100 IFOK(1)>1THEN37090
37105 CLS:PRINT:PRINTN$(1)" DEVRA DONC M'ABATTRE !":WAITC8*2:POKE#A000,CA(1)+10
37106 CA(1)=-3
37110 H=#A001:FORT6=2TO6:POKEH,AR(T6):H=H+1:POKEH,OK(T6):H=H+1:AR(T6)=2
37120 OK(T6)=3:NEXT:GA(1)=1:GA(2)=7:NB=7:C1=1:MN$(1)="GARDIEN":MC(1)=-3
37121 MF(1)=10*FO(1):MI(1)=0:MP(1)=ET(1)*3:MV(1)=VI(1):CB=1:MS(1)=0:MG(1)=0
37122 D=15:KO(1)=0:FORT6=3TO7:GA(T6)=3:NEXT:GOSUB53650
37130 H=#A001:FORT6=2TO6:AR(T6)=PEEK(H):H=H+1:OK(T6)=PEEK(H):H=H+1:NEXT
37140 CA(1)=PEEK(#A000)-10:IFOK(1)=3THEN37090
37141 IFFR<>0THEN37090ELSEW=W-52:RETURN
38000 IFMN$(MT)="Liane vivante"THEN38010
38001 IFOK(VM(MT))>1THEN38010
38002 RETURN
38010 FORT6=1TO6:IFUT%(VM(MT),T6)<>0THEN38015ELSENEXTT6:RETURN
38015 PRINT"1 "MN$(MT)" fouille "N$(VM(MT))"...":IFUT%(VM(MT),T6)=34THENTD=0
38020 PRINT:PRINT"Et lui derobe 1 "OB$(VM(MT),T6)" !!!":WAITC8:UT%(VM(MT),T6)=0
38030 OB$(VM(MT),T6)="":PRINT:WAITC8:IFOU(VM(MT))=T6THEN38040
38035 RETURN
38040 CG(VM(MT))=3:RETURN
40000 IFW6=634THENDOKEW6,48760ELSEDOKEW6,48720
40005 POKE48036,32:POKE48037,32:POKE48038,32:POKE48039,32
40010 POKEW7,9:POKE619,16:POKE620,0:CLS
40045 PRINT"PERSONNAGES CASTE PV ET CA":PRINT:CALLW3
40046 POKE48760,20:POKE48761,7:FORL=1TO6:IFET(L)=<0THENOK(L)=3
40048 IFAR(L)=2THENPRINT:GOTO40085
40050 PRINTRIGHT$(STR$(L),1);" "N$(L);
40060 FORII=LEN(N$(L))TO10:PRINT" ";:NEXT:IFOK(L)>0ANDOK(L)<3THEN40067
40061 IFOK(L)=3THENPRINT" MORT":ET(L)=0:GOTO40085
40065 PRINTC$(L);
40066 FORII=LEN(C$(L))TO9:PRINT" ";:NEXT:GOTO40070
40067 PRINTCHR$(27)"L"CF$(L);CHR$(27)"H";
40068 FORII=LEN(CF$(L))+2TO9:PRINT" ";:NEXT
40070 IFPV(L)<10ANDW6=621THENPRINT" ";
40075 PRINTRIGHT$(STR$(PV(L)),2);:PRINT" ";
40076 IFET(L)<10ANDW6=621THENPRINT" ";
40077 PRINTRIGHT$(STR$(INT(ET(L))),2);:PRINT" ";
40078 IFCA(L)=<-10THENPRINT"MI":GOTO40085
40079 IFCA(L)>-1ANDCA(L)<10ANDW6=621THENPRINT" ";
40084 PRINTRIGHT$(STR$(CA(L)),2)
40085 NEXTL
40086 H=49040:FORT=6TO1STEP-1:POKEH,27
40088 IFT=4THENPOKEH+1,7:H=H-40:GOTO40090
40089 POKEH+1,T:H=H-40
40090 NEXT:GOSUB1510:CALLW4:RETURN
41200 IFC$(I)=MA$THENC4=1:C3=10:GOTO41230
41210 IFC$(I)=DR$THENC4=11:C3=20:GOTO41230
41220 RETURN
41230 CLS:PRINT:PRINT"GRIMOIRE DE "N$(I):PRINT
41240 FORNB=C4TOC3:PRINT" ";
41250 PRINTSL%(I,NB)"x "S$(NB)
41270 NEXTNB:RETURN
41300 RS=INT((QI(I)-6)/14*(5+FNA(3)))
41320 IFC$(I)=MA$THENC4=1:C3=10:GOTO41340
41323 C4=11:C3=20
41340 IFRS<>0THEN41350
41345 FORNB=C4TOC3:SL%(I,NB)=2:NEXTNB:RETURN
41350 FORC5=1TORS:NB=FNA(10)+C4-1
41355 IFSL%(I,NB)<20THENSL%(I,NB)=SL%(I,NB)+1
41360 NEXTC5 :RETURN
41370 IFC$(I)<>MA$THEN41385ELSE41390
41385 IFC$(I)<>DR$THEND2=1:RETURN
41390 CLS:PRINT:INPUT"QUEL SORT ";SO$(I)
41400 FORC5=1TO20:IFSO$(I)=S$(C5)THEN41410
41405 NEXTC5:D2=1:RETURN
41410 IFSL%(I,C5)=0THENCLS:PRINT:PRINT" IMPOSSIBLE!":D2=1:WAITC8:RETURN
41420 GOTO41430+C5
41431 GOSUB41500:RETURN
41432 GOSUB41510:RETURN
41433 GOSUB41500:IFD2=1THENRETURNELSEGOSUB41520:RETURN
41434 GOSUB41500:RETURN
41435 GOSUB41500:RETURN
41436 GOSUB41500:RETURN
41437 GOSUB41500:RETURN
41438 GOSUB41510:RETURN
41439 RETURN
41440 RETURN
41441 GOSUB41530:RETURN
41442 GOSUB41500:RETURN
41443 GOSUB41500:RETURN
41444 GOSUB41530:RETURN
41445 RETURN
41446 GOSUB41530:RETURN
41447 GOSUB41510:IFD0=0THEND2=1:RETURNELSE41445
41448 GOSUB41510:RETURN
41449 GOSUB41510:RETURN
41450 GOSUB41510:IFD2=1THENRETURN
41451 GOSUB41530:RETURN
41500 IFCB<>1THEND2=1:RETURN
41505 D2=0:RETURN
41510 IFCB<>0THEND2=1:RETURN
41515 D2=0:RETURN
41520 IFC1=1THENVP(I)=1:RETURN
41521 CLS:PRINT:PRINT"SUR QUEL MONSTRE ?":Q3=C1:GOSUB8:VP(I)=VAL(A$):RETURN
41530 CLS:PRINT:PRINT"SUR QUI ?":Q3=6:GOSUB8:PG(I)=VAL(A$)
41535 IFAR(PG(I))=2THEND2=1
41536 RETURN
41540 Z0=0:CLS:PRINT:FORII=1TO6:IFUT%(I,II)>0THENPRINTII") "OB$(I,II):Z0=1
41551 NEXTII:IFZ0=0THEND2=1:CLS:RETURN
41555 PRINT"LEQUEL ? [7=aucun]":Q3=7:GOSUB8:OU(I)=VAL(A$)
41556 IFOU(I)=7THEND2=1:CLS:RETURN
41560 IFUT%(I,OU(I))=0THEND2=1:CLS:RETURN
41565 F9$=STR$(UU%(UT%(I,OU(I)))):F9$=RIGHT$(F9$,2):F9$=LEFT$(F9$,1)
41566 F9=VAL(F9$)+1
41570 ONF9GOTO41433,41438,41441,41431,41580
41580 GOSUB41500:IFD2=1THENRETURN
41590 GOTO41530
41600 FORT6=1TO6:ET(T6)=ET(T6)-(MR-10)*8:NEXTT6
41610 T6=90:Y=T6:D=1000:REPEAT:D=D+D/7:T6=T6-1:PRINT"*";
41620 SOUND4,T6,0:SOUND1,D,0:PLAY1,1,6,Y:Y=Y-T6/30:WAITY:UNTILD>5000
41630 PLAY0,0,0,0:EXPLODE:PRINT
41640 PRINT:PRINT"MIXTURE CHOC (pour le moins !!!)":WAITC8:GOTO10
42500 T1=7-E+(10-E1):T2=FNA(20):IFT1<T2THENE=0:RETURN
42540 E=1:RETURN
42600 IFF1<0THENF1=0
42620 IFF1>0THEN42630ELSEFR=0:C9=0:F1=1:RETURN
42630 FR=FNA(F1/3+1)-1:F1=F1+1:IFFR=<0THENFR=0:C9=0
42640 RETURN
42650 C6=FNA(3)-1:IFC6=0THENRETURN
42680 C7=FNA(3):CLS:PRINT:PRINT"1 "MN$(MT)" JETTE UN SORT...":WAITC8
42690 IFC7=1THEN42740
42691 IFC7=2THEN42791
42700 FORY=1TO6:IFMI(MT)>QI(Y)THENCA(Y)=CA(Y)+2
42720 IFCA(Y)>10THENCA(Y)=10
42730 NEXTY:RETURN
42740 FORY=1TO6:IFOK(Y)=3THENNEXTY:RETURN
42750 IFMI(MT)<QI(Y)THENNEXTY:RETURN
42755 C9=INT(MI(MT)*D/VI(Y)):ET(Y)=ET(Y)-C9:PRINTN$(Y)" PERD "C9" PV"
42780 IFET(Y)<=0THENOK(Y)=3:CF$(Y)="MORT":PRINTN$(Y)" SUCCOMBE"
42790 WAITC8:NEXTY:C9=0:RETURN
42791 FORY=1TOC1:MF(Y)=MF(Y)*2:NEXTY:RETURN
42800 PRINTN$(VM(MT))" SUCCOMBE":OK(VM(MT))=3:CF$(VM(MT))="MORT":WAITC8:RETURN
43100 GOSUB48200:IFE=1THEN43150
43110 C9=INT(12*FO(PT)/T6):GOSUB48050: GOTO10
43150 GOSUB48000:GOTO10
43200 GOSUB48200:IFE=1THEN43150
43210 C9=INT(20*FO(PT)/T6):GOSUB48050: GOTO10
43300 GOSUB48200:IFE=1THEN43150
43310 IFMS(VP(PT))<>1THEN43110
43320 C9=INT(30*FO(PT)/T6):GOSUB48050:GOTO10
43400 GOSUB48200:IFE=1THEN43150
43410 IFMG(VP(PT))<>3THEN43110
43420 GOTO43320
43500 GOTO43200
43600 O$="jette":GOSUB48300:IFE=1THENGOSUB48000:GOTO55210
43610 C9=INT(30*FO(PT)/T6):GOSUB48050:GOTO55210
43700 O$="lance":GOSUB48300:IFE=1THENGOSUB48000:GOTO55210
43710 C9=INT(20*AG(PT)/T6):GOSUB48050:GOTO55210
43800 GOSUB48200:IFE=1THEN43150
43810 C9=INT(7*FO(PT)/T6):GOSUB48050:GOTO10
43900 PRINTN$(PT)" decoche une fleche":ZAP:IFE=1THENGOSUB48000:GOTO48250
43910 C9=INT(12*AG(PT)/T6):GOSUB48050:GOTO48250
44000 O$="lance":GOSUB48300:IFE=1THENGOSUB48000:GOTO55210
44010 C9=INT(15*AG(PT)/T6):GOSUB48050:GOTO55210
44100 O$="projette":GOSUB48300:IFE=1THENGOSUB48000:GOTO48250
44110 C9=AG(PT)+FO(PT)/2:C9=INT(C9*15/T6):GOSUB48050:GOTO48250
44200 O$="utilise":GOSUB48300:IFE=1THENGOSUB48000:GOTO48250
44210 GOTO43910
44300 PRINTN$(PT)" fouette les monstres...":PO=7*AG(PT):GOSUB48100:GOTO10
44400 O$="lance":GOSUB48300:C9=INT(FO(PT)*8/T6):GOSUB48050:GOTO55210
44500 GOTO43200
44600 PRINTN$(PT)" lance un menhir !!!":IFFO(PT)>30THEN44620
44610 PRINT:PRINT"Le menhir tombe a 20cm de "N$(PT)"!!!":WAITC8:GOTO55210
44620 PO=1000:GOSUB48100:GOTO55210
44700 PRINTN$(PT)" deploie son filet ...":WAITC8
44710 FORT6=1TOC1:IFAG(PT)<MA(T6)THEN44730
44715 IFMS(T6)=1THEN44730
44720 PRINT"1 "MN$(T6)" est empetre !!!":WAITC8/2:KO(T6)=2
44730 NEXTT6:GOTO48250
44800 GOSUB48200:IFE=1THEN43150
44810 C9=INT(25*FO(PT)/T6):GOSUB48050:GOTO10
44900 O$="plante":GOSUB48200:E=15:E1=MC(VP(PT)):GOSUB42500:IFE=1THEN43150
44910 GOTO43210
45000 O$="utilise":GOSUB48300:IFE=1THENGOSUB48000:GOTO48250
45010 C9=INT(5*AG(PT)/T6):GOSUB48050:IFKO(VP(PT))=3ORMS(VP(PT))=1THEN45030
45020 PRINT:PRINT"LE MONSTRE EST EMPOISONNE!!!":MV(VP(PT))=MV(VP(PT))/3:WAITC8
45030 GOTO48250
45100 PRINT:PRINT"OBJET INUTILE ICI !":WAITC8:GOTO10
45200 IFMR=0THEN45250
45210 MR=MR+2
45220 PRINT:PRINT"OK C'EST DANS LA MARMITE !":WAITC8:GOTO55210
45250 PRINT:PRINT"ET LA MARMITE ???":WAITC8:GOTO10
45300 IFMR=0THEN45250
45310 MR=MR+3:GOTO45220
45400 IFMR=0THEN45250
45410 MR=MR+4:GOTO45220
45500 GOTO45700
45600 GOSUB41300:PRINT:PRINT"VOUS RECUPEREZ DES SORTS...":WAITC8:GOTO55210
45700 MR=1:PRINT:PRINT"QU'ALLEZ VOUS DONC NOUS MIJOTER ?":WAITC8*2:GOTO55210
45800 FORC9=1TONB:IFGA(C9)=VP(PG(PT))+6THENGA(C9)=PG(PT)
45810 NEXTC9:K=1:O$="utilise":GOSUB48300:GOTO55210
45900 O$="emploie":GOSUB48300:PO=QI(PT)^2:GOSUB48100:GOTO55210
46000 GOTO45600
46100 GOTO45900
46200 CA(PT)=-10:O$="met":GOSUB48300:GOTO10
46300 GOTO43200
46400 TD=1:PRINT:PRINT"OK!":WAITC8/2:GOTO10
46500 CLS:PRINT:PRINT:PRINT:PRINTN$(I)" DEPOSE SA STATUETTE"
46510 PRINT:PRINT"AU MILIEU DU CERCLE...":WAITC8*2:SE=1:GOTO10
46600 PRINTN$(PT)" utilise une potion..."
46610 F5=PG(PT):IFOK(F5)<>2THEN55210
46620 OK(F5)=0:CF$(F5)="OK":PRINT:PRINTN$(F5)" EST GUERI!!!":WAITC8:GOTO55210
46700 PRINTN$(PT)" utilise une potion..."
46710 F5=PG(PT):IFOK(F5)<>1THEN55210ELSE46620
46800 O$="utilise":GOSUB48300:PO=350:EXPLODE:GOSUB48100:GOTO55210
46900 PRINTN$(PT)" utilise un baume"
46910 C9=FNA(15):ET(PG(PT))=ET(PG(PT))+C9:PRINT:PRINTN$(PG(PT))" VA MIEUX!":WAITC8
46920 IFET(PG(PT))>PV(PG(PT))THENET(PG(PT))=PV(PG(PT))
46930 GOTO55210
47000 O$="lance":GOSUB48300:IFMS(VP(PT))=1THEN55210
47010 PRINT:PRINT"le monstre devient grabataire !!!":MV(VP(PT))=1:WAITC8:GOTO55210
47100 O$="seme":GOSUB48300:FORT6=1TOC1
47110 IFMS(T6)=1ORKO(T6)>1THEN47150
47120 PRINT"1 "MN$(T6)" FUIT !":KO(T6)=3
47150 NEXTT6:WAITC8:GOTO55210
47200 O$="provoque":GOSUB48300:KO(VP(PT))=3:PRINT:PRINT"1 "MN$(VP(PT))" est OCCIS !!!"
47210 WAITC8:GOTO55210
47300 PRINT:PRINTN$(PT)" tente une resurection...":GOSUB57200:GOTO55210
47400 O$="utilise":GOSUB48300:FO(PG(PT))=FO(PG(PT))*5:WAITC8:GOTO55210
47500 O$="utilise":GOSUB48300:CA(PG(PT))=-10:WAITC8:GOTO55210
48000 GOSUB50050:PRINT:PRINTO1$:WAITC8:RETURN
48050 PRINT:JJ=VP(PT):GOSUB50066:WAITC8:RETURN
48100 PRINT:FORJJ=1TOC1:C9=INT(PO/MV(JJ)):GOSUB50065:WAITC8:NEXTJJ:RETURN
48200 PRINTN$(PT)" "O$" 1 "MN$(VP(PT)):WAITC8:RETURN
48250 :VV%(PT,OU(PT))=VV%(PT,OU(PT))-1:IFVV%(PT,OU(PT))=1THEN48260ELSE10
48260 PRINT:PRINTN$(PT)" abandonne cet objet !":WAITC8:GOTO55210
48300 PRINTN$(PT)" "O$" 1 "OB$(PT,OU(PT)):WAITC8:RETURN
50030 QQ=FNA(9):GOTO50040+QQ
50041 O$="frappe":RETURN
50042 O$="cogne":RETURN
50043 O$="poignarde":RETURN
50044 O$="tabasse":RETURN
50045 O$="bouscule":RETURN
50046 O$="cingle":RETURN
50047 O$="lacere":RETURN
50048 O$="attaque":RETURN
50049 O$="charge":RETURN
50050 QQ=FNA(4):GOTO50060+QQ
50061 O1$="et loupe":RETURN
50062 O1$="et echoue":RETURN
50063 O1$="et manque":RETURN
50064 O1$="et rate":RETURN
50065 VP(PT)=JJ:IFKO(JJ)=3THENRETURN
50066 MP(JJ)=MP(JJ)-C9
50067 PRINT"1 "MN$(JJ)" PERD "C9" PV!!!"
50070 IFKO(VP(PT))=3THEN50090
50080 IFMP(VP(PT))>0THEN50090
50085 PRINT"ET MEURT!!!":KO(VP(PT))=3:IM(PT)=IM(PT)+1:EX(PT)=EX(PT)+1
50090 RETURN
50360 D0=1:SS=0:SE=0
50370 GOSUB1510:POKE620,3:POKE619,16:CLS
50380 PRINT" ******* CAMP *******"
50390 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT" VOUS POUVEZ..."
50400 PRINT:PRINT" 1) INSPECTER UN PERSONNAGE"
50410 PRINT" 2) PLIER BAGAGES"
50415 PRINT" 3) TEMPORISER LES COMBATS"
50420 Q3=3:GOSUB8
50425 IFVAL(A$)=3THENCLS:PRINT:PRINT:PRINT:PRINT" QUEL TEMPS ?...1 a 400"ELSE50430
50426 INPUTC8:IFC8<1ORC8>400THENC8=200
50427 GOTO50370
50430 CB=0:IFVAL(A$)=1THENGOSUB24000ELSE50440
50431 IFTL=1THENTL=0ELSE50370
50432 CLS:FORC9=1TO20:PING:WAIT10:GOSUB5560:NEXT
50440 GOSUB1510:POKEW7,27:POKE620,3:CLS:MR=0:RETURN
50600 GOSUB41540:IFD2=1THENRETURN
50605 GOSUB55149:GOSUB40000:GOSUB1500:CLS:RETURN
50610 GOSUB41370:IFD2=1THENRETURN
50615 GOSUB55250:GOSUB40000:GOSUB1500:CLS:RETURN
50800 CALLW4:TEXT:PRINTCHR$(17)
50805 GOSUB40000:POKE620,3:CLS
50810 PRINT:PRINT"VOUS ETES DEVANT L'ETAL D'UN CAMELOT.."
50811 PRINT:PRINT"VOULEZ VOUS FAIRE DE BONNES AFFAIRES ?"
50815 GETA$:GOSUB13:IFA$="O"THEN50900ELSEIFA$<>"N"THEN50815
50820 CLS:PRINT:PRINT"SERIEZ VOUS DONC TENTES PAR UN VOL ?"
50825 GETA$:IFA$="N"THENRETURN
50826 IFA$<>"O"THEN50825
50830 PRINT:PRINT"QUI OSERA ?":Q3=6:GOSUB8:Q4=VAL(A$):IFOK(Q4)>1THEN50830
50835 C9=FNA(10)+17
50840 IFC9>AG(Q4)THEN51000
50845 D=1:E=FNA(5)+2:GOSUB26500:WAITC8:RETURN
50900 PRINT:PRINT"QUI ?":Q3=6:GOSUB8:L=VAL(A$):IFOK(L)>1THEN50900
50910 PRINT:PRINT"VOUS POSSEDEZ "RI(L)" ECUS..."
50911 PRINT:INPUT"COMBIEN OFFREZ-VOUS ";E:IFE=<RI(L)THEN50920
50915 PRINT:PRINT"VOUS N'AVEZ PAS TANT !":WAITC8:CLS:GOTO50811
50920 Q4=FNA(100)+300:IFE=>Q4THEN50930
50925 PRINT:PRINT"CE LOT VAUT BIEN PLUS, MESSIRE !!!":WAITC8*2:CLS:GOTO50811
50930 RI(L)=RI(L)-E:E=INT(E/Q4):D=1:FORC9=1TOE:GOSUB25010:NEXTC9:WAITC8:CLS
50940 GOTO50811
51000 CLS:PRINT:PRINT"LE CAMELOT VOUS SURPREND !!!"
51005 PRINT:PRINT"UN OBJET MYSTERIEUX VOUS TOUCHE":FORC9=1TO5:ZAP:WAIT10:SHOOT:WAIT10
51006 NEXTC9
51010 C9=FNA(3)*10:ET(Q4)=ET(Q4)-C9
51015 IFET(Q4)=<0THENOK(Q4)=3:CF$(Q4)="MORT":ET(Q4)=0:GOTO51030
51020 C9=FNA(3)-1:GOTO51021+C9
51021 GOTO51030
51022 OK(Q4)=1:CF$(Q4)="EMPOI":GOTO51030
51023 OK(Q4)=2:CF$(Q4)="PARAL":GOTO51030
51025 GOSUB2:IFOP=0THENU7=1:GOSUB40000:GOSUB22000:RETURN
51030 IFC$(Q4)=VO$THEN50845ELSERETURN
52000 REM
52001 IFD0=0THENCLS:PRINT:PRINT:PRINT" NOUS SOMMES AU 10eme!!!":RETURN
52005 CLS
52010 PRINT"NOUS NOUS DIRIGEONS VERS ";:GOTO52015+(DI+1)/8
52016 PRINT"LE NORD":GOTO52020
52017 PRINT"L'EST":GOTO52020
52018 PRINT"LE SUD":GOTO52020
52019 PRINT"L'OUEST":GOTO52020
52020 T6=W-38200
52021 PRINT:F6=INT(T6/26)
52022 F7=T6-F6*26
52029 PRINT"NOUS SOMMES A "F6"CASES SUD"
52030 PRINT:PRINT"ET A "F7"CASES EST"
52040 PRINT:PRINT"DE L'ENTREE "
52070 PRINT:PRINT" [espace]"
52080 GETA$:IFA$<>" "THEN52080
52090 RETURN
52500 POKE620,3:CLS
52505 FORT6=1TO6
52510 IFOK(T6)=3THEN52590
52520 IFIM(T6)=C1THEN52531
52521 IFIM(T6)=0THEN52590
52522 C9=INT(IM(T6)/C1*1000)+FNA(C1)*10
52523 GOTO52550
52531 PRINT:PRINTN$(T6)" EST LE HEROS DE LA BATAILLE !":C9=2000+FNA(C1*100)
52550 PRINT:PRINTN$(T6)" S'ENRICHIT DE "C9" ECUS":RI(T6)=RI(T6)+C9
52560 WAITC8*2:NB=1:D=1:L=T6:FORC9=1TOIM(T6):GOSUB25015:WAITC8:NEXTC9:CLS
52590 NEXTT6:RETURN
52600 IFMS(MT)=1THENRETURN
52620 Y5=FNA(2)
52630 IFY5=2THENCLS:PRINT:PRINT"1 "MN$(MT)" FUIT!":KO(MT)=3:Y0=Y0+1:RETURN
52640 RETURN
53000 O1=0:K=0
53005 D=FNA(2)*(FNA(3)+1)+9
53080 FORI=1TO6:F2(I)=CA(I):F3(I)=FO(I):F0(I)=VI(I):IM(I)=0:NEXTI
53085 FORI=1TO6:KO(I)=0:NEXT:Y7=1
53100 C1=0:C2=0:SQ=0:PM=(FNA(4)+11)*D*2
53110 REPEAT:C1=C1+1:NB=FNA(2):IFNB=2THENDOKE#B0,IZ+125:GOTO53120
53115 DOKE#B0,IZ
53120 NB=FNA(8):FORZ=1TONB:READJ$(NB),M0(NB),M1(NB)
53140 GOSUB13:NEXTZ
53145 MN$(C1)=J$(NB):MS(C1)=M0(NB):MG(C1)=M1(NB):MF(C1)=(FNA(40)+D)*D
53160 IFMG(C1)=3THENMI(C1)=FNA(15)+D:C2=C2+1:SQ=SQ+MI(C1):GOTO53170
53165 MI(C1)=0
53170 MV(C1)=FNA(13)+5+INT(D/2):MA(C1)=FNA(10)+2+D
53190 MP(C1)=(FNA(11)+4)*D:MC(C1)=(INT(D/2)+FNA(7)-11)*(-1):PM=PM-MP(C1)
53215 UNTILPM<0ORC1=5:CALLW4:TEXT:PRINTCHR$(17)
53222 PAPER0:GOSUB40000:GOSUB53230:GOTO53500
53230 PM=0:CLS:GOSUB1510:POKE620,3:CLS:POKE48040,20
53236 PRINT" ********** COMBAT **********":PRINT
53240 FORI=1TOC1:IFKO(I)=3THEN53255
53250 PRINT" No"I"= 1"MN$(I);
53251 IFO1=1THENPRINT" "MP(I)ELSEPRINT
53255 NEXT:POKE48360,17
53256 POKE48361,7:PLOT1,8,"++++++++++++++++++++++++++++++++++++"
53260 IFW6=634THENDOKEW6,48400ELSEDOKEW6,48360
53265 POKEW7,9
53270 IFW3=#E76ATHENDOKE#27C,360:DOKE#278,48440
53280 RETURN
53500 CALLW3:NB=6+C1:FORI=1TONB:IFI>6THEN53550
53540 PR(I)=AG(I):GOTO53560
53550 PR(I)=MA(I-6)
53560 NEXTI:E=1:FORX=1TONB
53570 FORI=1TONB
53580 IFPR(I)<=PR(E)THEN53600
53590 E=I
53600 NEXTI
53610 GA(X)=E:PR(E)=0:NEXTX:CALLW4:GOSUB13
53650 GOSUB2
53652 IFOP=0THEN54991
53653 IFY7=1THENY7=0:GOTO53655
53654 GOSUB40000:GOSUB53230
53655 CLS:D2=0:CB=1:FR=0
53660 D1=0:FORI=1TO6:OU(I)=0:SO$(I)=""
53661 IFOK(I)=1THENET(I)=ET(I)-NI(I)
53662 GOSUB1500
53665 VP(I)=0:PG(I)=0:CLS
53670 IFOK(I)>1THENCG(I)=3:GOTO53750
53675 PRINT:PRINT" CHOIX DE "N$(I)":..."
53680 PRINT:PRINT" P)ARER"
53683 PRINT" U)TILISER"
53684 PRINT" S)ORTILEGE"
53685 IFD1=1THEN53700
53690 PRINT" F)UIR"
53700 GETA$
53702 IFA$="U"THENCG(I)=1:GOSUB41540:GOTO53740
53703 IFA$="S"THENCG(I)=2:GOSUB41370:GOTO53740
53704 IFA$="P"THENCG(I)=3:GOTO53740
53705 IFA$="F"THEN53720
53710 GOTO53700
53720 IFD1=1THEN53700ELSECG(I)=4:D1=1:GOSUB42600:IFFR=0THEN53721ELSE53800
53721 PING:W=38200+FNA(230):DI=FNA(4)*8-1
53722 IFPEEK(W)=25THEN53721ELSEGOSUB6:GOTO54995
53730 REM
53740 D1=1:IFD2=1THEND2=0:CLS:GOTO53665
53750 CLS:NEXTI:PRINT:PRINT:PRINT
53760 PRINT"DESIREZ VOUS REFAIRE LES CHOIX...? O/N"
53770 GETA$:IFA$="O"THEN53655
53775 IFA$<>"N"THEN53770
53800 D1=0:FORJ=1TONB:GOSUB13:IFCB=0THENRETURN
53812 GOSUB50030:GOSUB50050:IFGA(J)<7THEN55000
53825 MT=GA(J)-6:IFKO(MT)>1THENGOTO10
53835 POKE619,23:POKE620,0:CLS:PRINT:IFMI(MT)<>0THENGOSUB42650
53841 IFC6<>0THENC6=0:GOTO10
53845 IFD1=2THEND1=0:GOTO53852
53850 VM(MT)=FNA(6)
53851 IFVM(MT)>4THEND1=D1+1:GOTO53845
53852 IFNI(VM(MT))>D-2THENGOSUB52600
53853 E=10:IFY5=2THENY5=0:Y6=Y6+1:WAITC8:GOTO10
53854 E1=CA(VM(MT))
53855 GOSUB2:IFOP=0THEN54990
53856 IFOK(VM(MT))=3THEN53850
53860 GOSUB42500:GOSUB38000
53870 IFE=0THEN53890
53880 PRINT"1 "MN$(MT)" "O$" "N$(VM(MT)):PRINT
53881 FORY=1TO10:PRINT".";:WAIT5:NEXTY:PRINT" "O1$:WAITC8:GOTO10
53890 PRINT"1 "MN$(MT)" "O$" "N$(VM(MT)):PRINT
53900 C9=INT(MF(MT)/VI(VM(MT)))+1
53905 IFC9<1THENC9=1
53910 FORY=1TO10:PRINT".";:WAIT5:NEXTY:PRINTN$(VM(MT))" PERD "C9" PV":WAITC8
53920 ET(VM(MT))=ET(VM(MT))-C9
53930 IFET(VM(MT))<=0THENGOSUB42800:GOTO10
53935 IFOK(VM(MT))>0THEN10
53940 IFMG(MT)=0ORMG(MT)=3THEN10
53950 D3=FNA(3)-1
53960 IFD3>0THEN10
53970 IFMG(MT)=2THEN54000
53980 OK(VM(MT))=1:CF$(VM(MT))="EMPOI":PRINTN$(VM(MT))" EST EMPOISONNE!!!"
53990 WAITC8:GOTO10
54000 OK(VM(MT))=2:CF$(VM(MT))="PARAL":PRINTN$(VM(MT))" EST PARALYSE!!!":WAITC8
54989 NEXTJ
54990 IFCB=0THENRETURN
54991 POKE619,16:GOSUB2:IFOP=0THENU7=1:GOSUB40000:GOSUB22000:RETURN
54993 OP=1:FORPO=1TOC1:IFKO(PO)<>3THENOP=0
54994 NEXTPO:IFOP=0THEN53650
54995 IFMN$(1)="GARDIEN"THEN54999
54996 FORI=1TO6:CA(I)=F2(I):FO(I)=F3(I):VI(I)=F0(I):NEXTI:IFC9=0THEN54999
54997 GOSUB52500:IFD0=1THEN54999
54998 F1=F1-1:GOSUB40000:WAITC8*3
54999 GOSUB1510:POKEW7,27:POKE620,3:CLS:RETURN
55000 PT=GA(J):IFFR<>0THEN10
55001 IFK=0THEN55005
55002 IFOU(PT)=0ANDSO$(PT)=""THEN10
55005 IFAR(PT)=2THEN55030
55007 IFAR(PT)=1THENGOSUB31000
55015 IFVP(PT)<>0ANDKO(VP(PT))=3THEN10
55016 IFPG(PT)<>0ANDOK(PG(PT))=3THEN10
55030 IFOK(PT)>1THEN10
55035 POKE619,16:I=PT:GOSUB1500:CLS:PRINT
55037 FORT6=1TOC1:IFMV(T6)<1THENMV(T6)=1
55038 NEXTT6:T6=MV(VP(PT))
55040 GOTO55050+(CG(PT)*100)
55149 IFCB=0THENFORJ=1TO1
55150 E=10:E1=MC(VP(PT)):GOSUB42500:GOSUB50030:GOTO43000+(UT%(PT,OU(PT))*100)
55210 OB$(PT,OU(PT))="":UT%(PT,OU(PT))=0:OU(PT)=0
55220 GOTO10
55250 IFCB=0THENFORJ=1TO1
55260 FORC5=1TO20:IFSO$(PT)=S$(C5)THEN55270
55265 NEXTC5:CLS:GOTO10
55270 SL%(PT,C5)=SL%(PT,C5)-1:IFSL%(PT,C5)<0THENSL%(PT,C5)=0
55275 CLS:PRINT:PRINTN$(PT)" JETTE UN SORT...":WAITC8
55280 GOTO55200+(C5*100)
55300 FORT6=1TOC1:E=NI(PT):E1=MC(T6):GOSUB42500
55304 IFKO(T6)=3THENNEXTT6:GOTO10
55305 IFMS(T6)=1THEN55320
55306 IFMI(T6)>QI(PT)THEN55320
55307 IFKO(T6)=2THEN55330
55310 IFE=0THEN55330
55320 PRINT"1 "MN$(T6)" NE DORT PAS":WAITC8:NEXTT6:GOTO10
55330 PRINT"1 "MN$(T6)" ROUPILLE":WAITC8
55340 KO(T6)=2:MC(T6)=10:MV(T6)=MV(T6)-NI(PT):NEXTT6:GOTO10
55350 VI(PT)=VI(PT)+3:GOTO10
55400 CLS:GOSUB52000:RETURN
55500 E=NI(PT):E1=MC(PT)+INT(D/3):GOSUB42500
55510 IFE=0THEN55530
55520 PRINT:PRINT"1 "MN$(VP(PT))" Y EST INSENSIBLE!!!":WAITC8:GOTO10
55530 C9=INT(QI(PT)^2/MV(VP(PT))):PRINT:PRINT"1 "MN$(VP(PT))" PERD "C9" PV!!!"
55540 MP(VP(PT))=MP(VP(PT))-C9:GOSUB50070:WAITC8:GOTO10
55600 FORT6=1TOC1:MC(T6)=MC(T6)+NI(PT):IFQI(PT)>MI(T6)THENMV(T6)=MV(T6)-4
55610 NEXTT6:GOTO10
55700 FORT6=1TOC1:MF(T6)=MF(T6)/2:NEXTT6:GOTO10
55800 FORT6=1TO6:FO(T6)=FO(T6)*2:NEXTT6:GOTO10
55900 FORT6=1TO6:CA(T6)=-10:NEXTT6:GOTO10
56000 SS=1:PRINT:PRINT"LE MADEK EST LANCE !":WAITC8:GOTO10
56100 IFCB=0ANDMR<>0THEN56150
56101 IFCB=0THENPRINT:PRINT"LE LIRAM NE SE MANIFESTE PAS !!!":WAITC8:GOTO10
56102 PRINT:FORT6=1TOC1:C9=INT(QI(PT)*20/MV(T6))
56104 IFKO(T6)=3THEN56140
56106 IFMI(T6)<QI(PT)THEN56120
56110 PRINT"1 "MN$(T6)" Y EST INSENSIBLE":GOTO56140
56120 PRINT"1 "MN$(T6)" PERD "C9" PV!!!":MP(T6)=MP(T6)-C9:VP(PT)=T6:GOSUB50070
56140 WAITC8/2:NEXTT6:MR=0:GOTO10
56150 CLS:PRINT:PRINT:PRINT"LE FEU CREPITE SOUS LA MARMITE":FORT6=1TO20:PRINT".";:WAIT20:NEXTT6
56155 IFMR<6THEN56162
56157 IFMR>11THEN41600
56160 GOTO56160+MR*2
56162 PRINT:PRINT"IL MANQUE DES INGREDIENTS !!!":WAITC8:MR=0:GOTO10
56172 C9=42:GOTO56187
56174 C9=40:GOTO56187
56176 C9=43:GOTO56187
56178 C9=44:GOTO56187
56180 C9=41:GOTO56187
56182 C9=45
56187 FORT6=1TO6:IFOB$(I,T6)=""THEN56188ELSENEXTT6
56188 VV%(I,T6)=2:OB$(I,T6)=XX$(C9):UT%(I,T6)=C9
56189 PRINT:PRINT"LA FORMULE EST PRETE !!!":MR=0
56192 WAITC8*2:GOTO10
56200 IFSE=1THEN56210
56201 IFCB=1THEN56281
56205 PRINT:PRINTN$(I)" INVOQUE LES DIEUX":WAITC8*2:PRINT:PRINT"LES DIEUX SONT MUETS":WAITC8*2
56206 GOTO10
56210 CLS:PRINT:PRINT"LA STATUETTE S'ANIME SOUDAIN...":WAITC8*3
56220 PRINT:PRINT"LES DIEUX DAIGNENT VOUS PARLER !":PRINT:PRINT:PRINT" * ";
56225 T6=FNA(11):GOTO56230+T6
56231 O$="AUCUNE":GOTO56250
56232 O$="ARME":GOTO56250
56233 O$="NE":GOTO56250
56234 O$="PEUT":GOTO56250
56235 O$="FRANCHIR":GOTO56250
56236 O$="LA":GOTO56250
56237 O$="PORTE":GOTO56250
56238 O$="DU":GOTO56250
56239 O$="TEMPLE":GOTO56250
56240 O$="DE":GOTO56250
56241 O$="VIE"
56250 FORT6=1TOLEN(O$):PING:PRINTCHR$(ASC(MID$(O$,T6,1))+T6);:WAIT25:NEXT:PRINT" *"
56260 WAITC8:PRINT:PRINT:PRINT"DIX SERONT NECESSAIRES"
56270 PRINT:PRINT"POUR COMPRENDRE LE SENS DE LA VIE"
56280 WAIT800:SE=0:GOTO10
56281 FORT6=1TOC1:MV(T6)=3:NEXT
56282 FORT6=1TO6:IFVP(T6)<>0THENOK(T6)=1:CF$(T6)="EMPOI"
56283 NEXTT6:PRINT:PRINT"LES PUANTEURS DE L'ENFER ENVAHISSENT
56284 PRINT:PRINT"L'ENDROIT !!! ":WAITC8*2:GOTO10
56300 C9=FNA(15)+25:ET(PG(PT))=ET(PG(PT))+C9:PRINT:PRINTN$(PG(PT))" VA MIEUX!":WAITC8
56310 IFET(PG(PT))>PV(PG(PT))THENET(PG(PT))=PV(PG(PT))
56320 GOTO10
56400 PRINT: FORT6=1TOC1
56405 IFKO(T6)>0THEN56480
56410 IFMS(T6)=1THEN56445
56440 E=NI(PT):E1=MC(T6)-INT(D/4):GOSUB42500:IFE=0THEN56450
56445 PRINT"1 "MN$(T6)" S'EN MOQUE!!!":WAITC8:GOTO56480
56450 PRINT"1 "MN$(T6)" EST PETRIFIE!!!":WAITC8:KO(T6)=2:MV(T6)=FNA(3)+3
56480 NEXTT6:GOTO10
56500 FORT6=1TOC1
56504 IFKO(T6)=3THEN56535
56505 IFMI(T6)>QI(PT)THEN56535
56506 C9=4+D+FNA(10):IFC9>QI(PT)THEN56535
56507 IFMS(T6)=1THEN56520
56510 GOTO56535
56520 PRINT"1 "MN$(T6)" DISPARAIT!":WAITC8/2:KO(T6)=3:Y0=Y0+1
56530 EX(PT)=EX(PT)+1:IM(PT)=IM(PT)+1
56535 NEXTT6:GOTO10
56600 F5=PG(PT):IFOK(F5)<>1THEN10ELSE56810
56700 IFCB=0THEN56720
56710 O1=1:GOTO10
56720 IFF<>21THENWAITC8*2:PRINT:PRINT"LE KALAM EST INOPERANT ICI...":GOTO10
56725 T6=FNA(5):GOTO56725+T6*5
56730 O$="'TYRANN'... ELLE EST LA SOURCE DE TOUSLES MAUX !":GOTO56760
56735 O$="LE SCEPTRE N'ADMET POINT LE COMBAT !":GOTO56760
56740 O$="UN GESTE A L'OUEST VAUT MIEUX QU'UN EFFORT AU NORD!!!":GOTO56760
56745 O$="SCEPTRE DE PAIX ... SCEPTRE DE MORT ?":GOTO56760
56750 O$="LE SCEPTRE LUI APPORTERA LA PAIX...":GOTO56760
56755 O$="LA PERTE DU SCEPTRE ENTRAINA SA FOLIE..."
56760 CLS:PRINT:PRINT"ET DECRIPTE CES RUNES...":WAITC8:PRINT:PRINT:FORL=1TOLEN(O$)
56770 PRINTMID$(O$,L,1);:WAIT30:NEXT:WAITC8*2:GOTO10
56800 F5=PG(PT):IFOK(F5)<>2THEN10
56810 OK(F5)=0:CF$(F5)="OK":PRINT:PRINTN$(F5)" EST GUERI!!!":WAITC8:GOTO10
56900 W=38200:PRINT:PRINT"TELEPORTATION APPELEE...":WAITC8*2:TL=1:GOTO10
56901 IFC9=2THENWAITC8:GOTO10
57000 FORT6=1TO6:IFOK(T6)=3THEN57030
57020 ET(T6)=PV(T6):OK(T6)=0:CF$(T6)="OK"
57030 NEXTT6:PRINT:PRINT"TOUS LES VIVANTS SONT RETABLIS!!!":WAITC8:GOTO10
57100 D=1:E=INT(QI(I)/2):GOSUB26500:WAITC8:GOTO10
57200 F5=PG(PT):ET(F5)=1:OK(F5)=0:CF$(F5)="OK":PRINT:PRINTN$(F5)" VA BIEN!!!"
57210 WAITC8:RETURN
58000 DATAEpee,100,Epee a deux mains,100,Epee anti-esprits,100
58005 DATAEpee anti-magie,100,Enorme barre,100,Lance,102,Poignard,202
58010 DATAGourdin,500,Arc,509,Javelle,502,Boomerang,505,Fronde,507
58015 DATAFouet,230,Caillou,502,Cimetere,100,Menhir,132,Filet,233
58020 DATAHache de bourreau,100,Hallebarde,100,Sarbacane,205,Rossignol,210
58025 DATAOs,512,Soufre,512,Mygale,512,Marmite,410
58030 DATAParchemin,412,Marmite,410,Anneau,442,Baton magique,432
58035 DATATablette gravee,312,Crosse,332,Bague,330
58040 DATAMasse d'arme,300,Boussole,310,Statuette,312,Anti-paralysie,522
58045 DATAAnti-poison,522,Baril de poudre,532,Fiole de soins,522
58046 DATAPotion de senilite,402,Poudre de panique,432,Eclair mortel,402
58047 DATAEssence vitale,422,Elixir,442,Onguent,442
58050 DATAYPAFET,KADEO,KEMPY,TASAWAD,ZADEQ,YDAMA,ISHUL,MADEK,LIRAM,SEGOY
58060 DATAASEKO,OKOY,ZINAK,INUK,KALAM,OHW,GOHO,XOLUK,GOLAM,YADEH
59900 DATADrole d'animal,1,2,Horreur,,,Liane vivante,,1
59910 DATARoi dragon,,3,Demon,1,3,Dieu maudit,,2
59920 DATAVer geant,,1,Cthulhu,1,2
59930 DATAGolem,,,Dragon noir,,3,Titan,,,Colosse,,,Eminence noire,1,1
59940 DATALuminescence,1,3,Hydre,,1,Chevalier blanc,,3
|
